Cuenta cuántos valores diferentes toma una lista en Mathematica

Question

Me gustaría obtener la cantidad de valores diferentes que se encuentran en una lista.

Por ejemplo:

La salida para la Lista a={1,2,3,4,5} sería 5 mientras que sería 2 para b={1,1,1,2,2}.

Answer 1

Sólo por diversión, todos los siguientes comandos también dan el resultado deseado:

Length@Gather@l 

Length@Union@l 

Length@Tally@l 

Count[BinCounts@l, Except@0] 

Count[BinLists@l, Except@{}] 

Length@Split@Sort@l 

Length@GatherBy[l, # &] 

Length@Split@SortBy[l, # &] 

Y muchos más, por supuesto.

Editar

Aquí es un pequeño experimento de distribución (no grave)

l = RandomInteger[{1, 10^2}, 10^7]; 
t2[x_] := {Timing[x], ToString[HoldForm@x]}; 
SetAttributes[t2, HoldAll] 
Grid[Reverse /@ 
    {t2[Length@DeleteDuplicates[l]], 
    t2[Length@Tally[l]], 
    t2[Length@Gather[l]], 
    t2[Count[BinCounts[l], Except@0]], 
    t2[Length@Union[l]], 
    t2[Length@Split@Sort@l], 
    t2[Count[BinLists[l], Except@0]]}, 
Frame -> All] 

Por cierto: Tenga en cuenta la diferencia entre BinLists[ ] y BinCounts[ ]

Editar

una vista más detallada de DeleteDuplicates vs Tally

t = Timing; 
ListLinePlot@Transpose@ 
    Table[l = RandomInteger[{1, 10^i}, 10^7]; 
    {Log@First@t@Length@DeleteDuplicates@l, 
    Log@First@t@Length@Tally@l}, 
    {i, Range[7]}] 

¡Cuidado! ¡Diagrama de registro!

Answer 2

Utilice DeleteDuplicates (o Union en versiones anteriores) para eliminar los elementos duplicados. Luego puede contar los elementos en la lista devuelta.

In[8]:= Length[DeleteDuplicates[a]] 
Out[8]= 5 

In[9]:= Length[DeleteDuplicates[b]] 
Out[9]= 2 

Answer 3

Length[DeleteDuplicates[a]] 

que hacer el truco. Dependiendo de qué otra cosa vaya a hacer, puede usar Union o Tally en lugar de DeleteDuplicates.

Answer 4

CountDistinct[a] 

haría también hacer el truco, que es una función introducida en Mathematica 10.0, una función equivalente a

Length[DeleteDuplicates[a]]