Indización de lista en mathematica

Question

Sea S sea un vector con elementos únicos, y s un subconjunto de él, también con elementos únicos; por ejemplo, S={1,2,3,4,5,6} y s={1,3,4,6}. Ahora dado otro vector c={7,8,9,7}, ¿cómo puedo crear un vector C=[7,0,8,9,0,7], es decir, si S[[i]] es un elemento en s, entonces C[[i]] es igual al elemento en c con el mismo índice como S[[i]] en s, otro cero.

Lo que tengo en este momento se ve como

C=Array[0&,Length[S]]; 
j=1; 
For[i=1,i<=Length[S],i++,If[MemberQ[s,S[[i]]],C[[i]]=c[[j]];j=j+1;]]; 

Esto funciona, pero viniendo de un fondo de MATLAB, odio for bucles y la operación anterior es una operación de indexación trivial en MATLAB. Estoy seguro de que hay una manera más inteligente de lograr esto, un estilo la mathematica. ¿Alguien tiene sugerencias?

Answer 1

Esto es más rápido que lo que se ha publicado hasta ahora:

ss = {1, 2, 3, 4, 5, 6}; s = {1, 3, 4, 6}; c = {7, 8, 9, 7}; 

Replace[ss, Dispatch@Append[Thread[s -> c], _ -> 0], 1] 

Answer 2

elementos

va a sustituir de S, ya sea con un elemento en C o con 0, así que:

ss = {1, 2, 3, 4, 5, 6} 
s = {1, 3, 4, 6} 
c = {7, 8, 9, 7} 
r = Append[MapThread[Rule, {s, c}], Rule[_, 0]] 
answer = Map[Replace[#, r] &, ss] 

Answer 3

Aquí está una manera. Probablemente haya muchos otros.

s = {1, 2, 3, 4, 5, 6}; 
subS = {1, 3, 4, 6}; 
c = {7, 8, 9, 7}; 
d= s /. {x_Integer :> If[MemberQ[subS, x], c[[Position[subS, x][[1, 1]]]], 0]} 

He utilizado nombres de variables de minúscula en todo el sentido de los símbolos definidos por el usuario.

Las llaves usadas de Mathematica se utilizan para vectores, listas, matrices y tablas.

Answer 4

ss = {1, 2, 3, 4, 5, 6}; 
s = {1, 3, 4, 6}; 
c = {7, 8, 9, 7}; 
ss /. Join[MapThread[Rule, {s, c}],Thread[Rule[Complement[ss, s], 0]]] 

EDITAR o:

answer = 0 ss; answer[[Position[ss, #, 1] & /@ s // Flatten]] = c; 

Answer 5

Si S es siempre de la forma {1, 2, ..., n}, (por ejemplo, Range[n]) entonces esta solución que usa SparseArray es aproximadamente dos veces más rápida que @Mr. La respuesta de asistente en mi prueba para listas muy grandes:

Normal[SparseArray[Thread[s -> c], n, 0]]