Cómo colorear mezcla (colorear por valor alfa especificado) el área del lienzo usando GDI puro?

Question

Me gustaría mezclar colores (colorear por valor alfa especificado) el área de un lienzo utilizando Windows GDI puro (sin GDI +, DirectX o similar, sin OpenGL, sin ensamblador o bibliotecas de terceros).

He creado la siguiente función y me gustaría saber si hay una manera más eficiente o más fácil de hacer esto:

procedure ColorBlend(const ACanvas: HDC; const ARect: TRect; 
    const ABlendColor: TColor; const ABlendValue: Integer); 
var 
    DC: HDC; 
    Brush: HBRUSH; 
    Bitmap: HBITMAP; 
    BlendFunction: TBlendFunction; 
begin 
    DC := CreateCompatibleDC(ACanvas); 
    Bitmap := CreateCompatibleBitmap(ACanvas, ARect.Right - ARect.Left, 
    ARect.Bottom - ARect.Top); 
    Brush := CreateSolidBrush(ColorToRGB(ABlendColor)); 
    try 
    SelectObject(DC, Bitmap); 
    Windows.FillRect(DC, Rect(0, 0, ARect.Right - ARect.Left, 
     ARect.Bottom - ARect.Top), Brush); 
    BlendFunction.BlendOp := AC_SRC_OVER; 
    BlendFunction.BlendFlags := 0; 
    BlendFunction.AlphaFormat := 0; 
    BlendFunction.SourceConstantAlpha := ABlendValue; 
    Windows.AlphaBlend(ACanvas, ARect.Left, ARect.Top, 
     ARect.Right - ARect.Left, ARect.Bottom - ARect.Top, DC, 0, 0, 
     ARect.Right - ARect.Left, ARect.Bottom - ARect.Top, BlendFunction); 
    finally 
    DeleteObject(Brush); 
    DeleteObject(Bitmap); 
    DeleteDC(DC); 
    end; 
end; 

Para la noción de lo que esta función no debería ver el siguiente (que discriminan imágenes :-):

y el código que puede hacer que this image hacia el lado izquierdo superior de la forma de la forma indicada anteriormente:

uses 
    PNGImage; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Image: TPNGImage; 
begin 
    Image := TPNGImage.Create; 
    try 
    Image.LoadFromFile('d:\6G3Eg.png'); 
    ColorBlend(Image.Canvas.Handle, Image.Canvas.ClipRect, $0000FF80, 175); 
    Canvas.Draw(0, 0, Image); 
    finally 
    Image.Free; 
    end; 
end; 

¿Hay una manera más eficiente de hacer esto usando GDI puro o Delphi VCL?

Answer 1

¿Has probado el Canvas Drawing con AlphaBlend?

algo así como

Canvas.Draw(Arect.Left, ARect.Top, ABitmap, AAlphaBlendValue); 

combinado con un fillRect para el color de fusión

actualización: Y aquí está un cierto código, lo más cerca posible a su interfaz, pero pura VCL.
Puede que no sea tan eficiente, pero mucho más simple (y algo portátil).
Como Remy dicho, para pintar en un formulario de una manera persistente seudo, que tendría que utilizar OnPaint ...

procedure ColorBlend(const ACanvas: TCanvas; const ARect: TRect; 
    const ABlendColor: TColor; const ABlendValue: Integer); 
var 
    bmp: TBitmap; 
begin 
    bmp := TBitmap.Create; 
    try 
    bmp.Canvas.Brush.Color := ABlendColor; 
    bmp.Width := ARect.Right - ARect.Left; 
    bmp.Height := ARect.Bottom - ARect.Top; 
    bmp.Canvas.FillRect(Rect(0,0,bmp.Width, bmp.Height)); 
    ACanvas.Draw(ARect.Left, ARect.Top, bmp, ABlendValue); 
    finally 
    bmp.Free; 
    end; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Image: TPNGImage; 
begin 
    Image := TPNGImage.Create; 
    try 
    Image.LoadFromFile('d:\6G3Eg.png'); 
    ColorBlend(Image.Canvas, Image.Canvas.ClipRect, $0000FF80, 175); 
    Canvas.Draw(0, 0, Image); 
    // then for fun do it to the Form itself 
    ColorBlend(Canvas, ClientRect, clYellow, 15); 
    finally 
    Image.Free; 
    end; 
end;