Crear gráfico a partir de datos de matriz y no en el rango

Question

¿es posible crear un gráfico (por ejemplo, gráfico de línea de eje Y doble) no desde rangos, sino desde datos de matriz? ¿Si es así, cómo?

Answer 1

Sí. Puede asignar matrices a las propiedades XValues y Values de un objeto Series en un gráfico. Ejemplo:

Dim c As Chart 
Dim s As Series 
Dim myData As Variant 

Set c = ActiveChart ' Assumes a chart is currently active in Excel... 
Set s = c.SeriesCollection(1) 

myData = Array(9, 6, 7, 1) ' or whatever 
s.Values = myData 

Answer 2

Puede asignar matrices para trazar la serie en Excel 2007 en adelante, pero en versiones anteriores Creo que hay un límite de 255 caracteres para la longitud de cada serie. Un método que he utilizado para evitar esta restricción se muestra en el siguiente ejemplo de paseo aleatorio:

Sub ChartArray() 

Dim x(0 To 1000, 0 To 0) As Double 
Dim y(0 To 1000, 0 To 0) As Double 
x(0, 0) = 0 
y(0, 0) = 0 
For i = 1 To 1000 
    x(i, 0) = i 
    y(i, 0) = y(i - 1, 0) + WorksheetFunction.NormSInv(Rnd()) 
Next i 

Charts.Add 
ActiveChart.ChartType = xlXYScatterLinesNoMarkers 
With ActiveChart.SeriesCollection 
    If .Count = 0 Then .NewSeries 
    If Val(Application.Version) >= 12 Then 
     .Item(1).Values = y 
     .Item(1).XValues = x 
    Else 
     .Item(1).Select 
     Names.Add "_", x 
     ExecuteExcel4Macro "series.x(!_)" 
     Names.Add "_", y 
     ExecuteExcel4Macro "series.y(,!_)" 
     Names("_").Delete 
    End If 
End With 
ActiveChart.ChartArea.Select 

End Sub 

Un método alternativo es asignar nombres a las matrices (similares a solución anterior) y luego configurar la serie para referirse a los nombres asignados. Esto funciona bien en todas las versiones siempre que guarde en formato xls, pero parece haber una limitación de longitud para las matrices con nombre de 8192 caracteres al guardar en los nuevos formatos xlsx/xlsm/xlsb.