¿Cómo 'uso' un módulo Perl en un directorio que no está en @INC?

Question

Tengo un módulo en el directorio padre de mi script y me gustaría 'usarlo'.

Si hago

use '../Foo.pm'; 

tengo errores de sintaxis.

he tratado de hacer:

push @INC, '..'; 
use EPMS; 

y .. al parecer no se presenta en @INC

me estoy volviendo loco! ¿Qué pasa aquí?

Answer 1

use tiene lugar en tiempo de compilación, por lo que esto funcionaría:

BEGIN {push @INC, '..'} 
use EPMS; 

embargo, la mejor solución es use lib, que es una manera más agradable de escribir lo anterior:

use lib '..'; 
use EPMS; 

En Sin embargo, si está ejecutando desde un directorio diferente, se recomienda el uso de FindBin:

use FindBin;      # locate this script 
use lib "$FindBin::RealBin/.."; # use the parent directory 
use EPMS; 

Answer 2

Debe procesar push antes de use - y use se procesa antes. Entonces, necesitarás un BEGIN { push @INC, ".."; } para tener una oportunidad, creo.

Answer 3

'use lib' es la respuesta, como @ephemient mencionado anteriormente. Otra opción es usar require/import en lugar de usar. Significa que el módulo no se cargará en tiempo de compilación, sino en tiempo de ejecución.

Eso le permitirá modificar @INC como lo intentó allí, o podría pasar requerir una ruta de acceso al archivo en lugar del nombre del módulo. Desde 'perldoc -f require':

si expr es un bareword, la requieren asume una extensión ".pm" y sustituye '::' con '/' en el nombre de archivo para usted, para hacer más fácil a cargue los módulos estándar. Esta forma de carga de módulos no implica el riesgo de de alterar su espacio de nombres.

Answer 4

Existen varias formas de modificar @INC.

• conjunto PERL5LIB, como se documenta en perlrun

• utilizar el interruptor -I en la línea de comandos, también documentado en perlrun. También puede aplicar esto automáticamente con PERL5OPT, pero simplemente use PERL5LIB si va a hacer eso.

• use lib dentro de su programa, aunque esto es frágil ya que otra persona en una máquina diferente podría tenerlo en un directorio diferente.

• Modifique manualmente @INC, asegurándose de hacerlo en tiempo de compilación si desea instalar un módulo con el uso. Eso es demasiado trabajo sin embargo.

Answer 5

personalmente prefiero mantener mis módulos (aquellos que escribo para mí mismo o para sistemas que puedo controlar) en un directorio determinado, y también para colocarlos en un subdirectorio. Como en:

/www/modules/MyMods/Foo.pm 
/www/modules/MyMods/Bar.pm 

Y entonces, ¿dónde las uso:

use lib qw(/www/modules); 
use MyMods::Foo; 
use MyMods::Bar; 

Como acotación al margen .. cuando se trata de empujar, yo prefiero la grasa de flecha coma:

push @array => $pushee; 

Pero eso es solo una cuestión de preferencia.

Answer 6

Según lo informado por "perldoc uso -f":

Es exactamente equivalente a
BEGIN { require Module; import Module LIST; }
excepto que el módulo debe ser un bareword.

Poniendo eso de otra manera, el "uso" es equivalente a:

• funcionamiento en tiempo de compilación,
• convertir el nombre del paquete a un nombre de archivo,
• require -ing ese nombre de archivo y
• import - ese paquete.

Así, en lugar de llamar a su uso, puede llamar a requerir e importación dentro de un bloque BEGIN:

BEGIN { 
    require '../EPMS.pm'; 
    EPMS->import(); 
} 

Y, por supuesto, si su módulo en realidad no hace ningún símbolo de exportación u otra inicialización cuando usted llama a la importación, puede dejar esa línea:

BEGIN { 
    require '../EPMS.pm'; 
}