¿Cómo uso las constantes de un módulo Perl?

Question

Si defino una constante en un módulo Perl, ¿cómo uso esa constante en mi programa principal? (¿O cómo puedo llamar a esa constante en el programa principal?)

Answer 1

Las constantes se pueden exportar al igual que otros símbolos del paquete. Utilizando el módulo estándar Exporter, puede exportar las constantes de un paquete como este:

package Foo; 
use strict; 
use warnings; 

use base 'Exporter'; 

use constant CONST => 42; 

our @EXPORT_OK = ('CONST'); 

1; 

Luego, en un script de cliente (u otro módulo)

use Foo 'CONST'; 
print CONST; 

Puede usar el hash %EXPORT_TAGS (ver el Documentación del exportador) para definir grupos de constantes que se pueden exportar con un solo argumento de importación.

Actualización: Aquí hay un ejemplo de cómo usar la característica %EXPORT_TAGS si tiene múltiples constantes.

use constant LARRY => 42; 
use constant CURLY => 43; 
use constant MOE => 44; 

our @EXPORT_OK = ('LARRY', 'CURLY', 'MOE'); 
our %EXPORT_TAGS = (stooges => [ 'LARRY', 'CURLY', 'MOE' ]); 

entonces se puede decir

use Foo ':stooges'; 
print "$_\n" for LARRY, CURLY, MOE; 

Answer 2

Las constantes son sólo los submarinos con prototipo de vacío, por lo que se pueden exportar como cualquier otro sub.

# file Foo.pm 
package Foo; 
use constant BAR => 123; 
use Exporter qw(import); 
our @EXPORT_OK = qw(BAR); 


# file main.pl: 
use Foo qw(BAR); 
print BAR; 

Answer 3

Para ampliar las respuestas anteriores, dado que las constantes son en realidad submarinos, puede también llamar directamente:

use Foo; 
print Foo::BAR; 

Answer 4

Es posible que desee considerar el uso de Readonly en lugar de constante.

Answer 5

package Foo; 
use Readonly; 
Readonly my $C1 => 'const1'; 
Readonly our $C2 => 'const2'; 
sub get_c1 { return $C1 } 
1; 

perl -MFoo -e 'print "$_\n" for Foo->get_c1, $Foo::C2' 

Answer 6

a añadir a la bolsa de trucos, ya que una constante es simplemente una subrutina incluso se puede llamar como un método de clase.

package Foo; 
use constant PI => 3.14; 

print Foo->PI; 

Si usted tiene un montón de constantes es una buena manera de conseguir en el que de vez en cuando sin tener que exportar a todos. Sin embargo, a diferencia de Foo::PI o exportando PI, Perl no compilará Foo->PI por lo que incurrirá en el costo de una llamada a método (que probablemente no importe).