Hosting CLR en Delphi con/sin JCL - ejemplo

Question

¿Alguien puede publicar aquí un ejemplo de cómo alojar CLR en Delphi? He leído question similar aquí pero no puedo usar JCL porque quiero alojarlo en Delphi 5. Gracias.

---

EDIT: Este article sobre el recibimiento de CLR en Fox Pro parece prometedor, pero no sé cómo acceder a clrhost.dll de Delphi.

---

Edición 2: que renunciar a Delphi 5 requisito. Ahora estoy probando JCL con Delphi 7. Pero nuevamente no puedo encontrar ningún ejemplo. Aquí es lo que tengo hasta ahora:

Mi C# ensamblaje:

namespace DelphiNET 
{ 
    public class NETAdder 
    { 
     public int Add3(int left) 
     { 
      return left + 3; 
     } 
    } 
} 

he recopilado a DelphiNET.dll.

Ahora quiero utilizar este conjunto de Delphi:

uses JclDotNet, mscorlib_TLB; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    clr: TJclClrHost; 
    ads: TJclClrAppDomainSetup; 
    ad: TJclClrAppDomain; 
    ass: TJclClrAssembly; 
    obj: _ObjectHandle; 
    ov: OleVariant; 
begin 
    clr := TJclClrHost.Create(); 
    clr.Start; 
    ads := clr.CreateDomainSetup; 
    ads.ApplicationBase := 'C:\Delhi.NET'; 
    ads.ConfigurationFile := 'C:\Delhi.NET\my.config'; 
    ad := clr.CreateAppDomain('myNET', ads); 
    obj := (ad as _AppDomain).CreateInstanceFrom('DelphiNET.dll', 'DelphiNET.NETAdder'); 
    ov := obj.Unwrap; 
    Button1.Caption := 'done ' + string(ov.Add3(5)); 
end; 

Esto termina con el error: EOleError: Variante no hace referencia a un objeto de automatización

No he trabajado con Delphi durante mucho tiempo, así que estoy atrapado aquí ...

---

Solución: T Aquí había un problema en la visibilidad COM que no es por defecto. Este es el ensamblado de .NET correcta:

namespace DelphiNET 
{ 
    [ComVisible(true)] 
    public class NETAdder 
    { 
     public int Add3(int left) 
     { 
      return left + 3; 
     } 
    } 
} 

---

Nota importante:

Cuando se trabaja con .NET de Delphi, es importante llamar Set8087CW($133F); al comienzo de su programa (es decir, antes Application.Initialize;). Delphi ha habilitado excepciones de coma flotante de forma predeterminada (consulte this) y al CLR no le gustan. Cuando los tuve habilitados, mi programa se bloqueó extrañamente.

Answer 1

La clase tiene que ser comvisible. Lo cual podría no ser el caso si tiene ComVisible (falso) para toda la asamblea.

clases .NET serán compatibles IDispatch de forma predeterminada, por lo que la muestra debería funcionar bien, si la clase es muy ComVisible ..

Pero tira hacia abajo al mínimo en primer lugar. Coloque su archivo exe en la misma carpeta que su ensamblado .Net y omita el archivo de configuración y la base de la aplicación.

Antes de que algo se mezcle, la excepción sucede aquí, ¿no?

ov := obj.Unwrap; 

Answer 2

Aquí van:

program CallDotNetFromDelphiWin32; 

{$APPTYPE CONSOLE} 

uses 
    Variants, JclDotNet, mscorlib_TLB, SysUtils; 

var 
    Host: TJclClrHost; 
    Obj: OleVariant; 
begin 
    try 
    Host := TJclClrHost.Create; 
    Host.Start; 
    WriteLn('CLRVersion = ' + Host.CorVersion); 

    Obj := Host.DefaultAppDomain.CreateInstance('DelphiNET', 'DelphiNET.NETAdder').UnWrap; 
    WriteLn('2 + 3 = ' + IntToStr(Obj.Add3(2))); 

    Host.Stop; 
    except 
    on E: Exception do 
     Writeln(E.Classname, ': ', E.Message); 
    end; 
end. 

Nota: asume que el tipo DelphiNET.NETAdder y el método Add3 en DelphiNet.dll es ComVisible. Gracias a Robert.

actualización:

Cuando se utiliza la reflexión que no es necesario el atributo ComVisible. El siguiente ejemplo incluso funciona sin ser ComVisible.

Assm := Host.DefaultAppDomain.Load_2('NetAddr'); 
T := Assm.GetType_2('DelphiNET.NETAdder'); 
Obj := T.InvokeMember_3('ctor', BindingFlags_CreateInstance, nil, null, nil); 
Params := VarArrayOf([2]); 
WriteLn('2 + 3 = ' + IntToStr(T.InvokeMember_3('Add3', BindingFlags_InvokeMethod, nil, Obj, PSafeArray(VarArrayAsPSafeArray(Params))))); 

Answer 3

Aquí hay otra opción.

Ese es el código C#. E incluso si no quiere usar my unmanaged exports, aún así le explicará cómo usar mscoree (el material de CLR hosting) sin pasar por IDispatch (IDispatch es bastante lento).

using System; 
using System.Collections.Generic; 
using System.Text; 
using RGiesecke.DllExport; 
using System.Runtime.InteropServices; 

namespace DelphiNET 
{ 

    [ComVisible(true)] 
    [InterfaceType(ComInterfaceType.InterfaceIsIUnknown)] 
    [Guid("ACEEED92-1A35-43fd-8FD8-9BA0F2D7AC31")] 
    public interface IDotNetAdder 
    { 
     int Add3(int left); 
    } 

    [ComVisible(true)] 
    [ClassInterface(ClassInterfaceType.None)] 
    public class DotNetAdder : DelphiNET.IDotNetAdder 
    { 
     public int Add3(int left) 
     { 
     return left + 3; 
     } 
    } 

    internal static class UnmanagedExports 
    { 
     [DllExport("createdotnetadder", CallingConvention = System.Runtime.InteropServices.CallingConvention.StdCall)] 
     static void CreateDotNetAdderInstance([MarshalAs(UnmanagedType.Interface)]out IDotNetAdder instance) 
     { 
     instance = new DotNetAdder(); 
     } 
    } 
} 

Esta es la declaración de interfaz de Delphi:

type 
    IDotNetAdder = interface 
    ['{ACEEED92-1A35-43fd-8FD8-9BA0F2D7AC31}'] 
    function Add3(left : Integer) : Integer; safecall; 
    end; 

Si utiliza las exportaciones no administrados, puede hacerlo de esta manera:

procedure CreateDotNetAdder(out instance : IDotNetAdder); stdcall; 
    external 'DelphiNET' name 'createdotnetadder'; 

var 
    adder : IDotNetAdder; 
begin 
    try 
    CreateDotNetAdder(adder); 
    Writeln('4 + 3 = ', adder.Add3(4)); 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
end. 

Cuando me adapto muestra de Lars', lo haría se ve así:

var 
    Host: TJclClrHost; 
    Obj: IDotNetAdder; 
begin 
    try 
    Host := TJclClrHost.Create; 
    Host.Start(); 
    WriteLn('CLRVersion = ' + Host.CorVersion); 

    Obj := Host.DefaultAppDomain 
       .CreateInstance('DelphiNET', 
           'DelphiNET.DotNetAdder') 
       .UnWrap() as IDotNetAdder; 
    WriteLn('2 + 3 = ', Obj.Add3(2)); 

    Host.Stop(); 
    except 
    on E: Exception do 
     Writeln(E.Classname, ': ', E.Message); 
    end; 
end. 

En este caso, podría eliminar la clase "UnmanagedExports" del código C#, por supuesto.