Actionscript - Obtenga el nombre de la función actual

Question

Quiero obtener el nombre de una función desde el interior de esa función. por ejemplo:

function blah() { 
    //I want to get the string "blah" here, from the function's name 
} 

O al menos el objeto Function?

Answer 1

Use arguments.callee para obtener una referencia a la función actual.

Si desea obtener el nombre de la función, es un poco más complicado: todas las funciones se tratan como cierres de métodos (fragmentos de código que pueden transmitirse como argumento), por lo que no poseen una referencia a un adjunto tipo de clase, ni tienen un "nombre actual".

Sin embargo, si (y única si) el método es pública, y que desea obtener el nombre del método de la declaración de la clase de un objeto de instancia que contiene el método, puede utilizar describeType:

public function someFunction() : void { 
    var callee:Function = arguments.callee; 
    trace (getFunctionName(callee, this)); // ==> someFunction 
} 

private function someOtherFunction() : void { 
    var callee:Function = arguments.callee; 
    trace (getFunctionName(callee, this)); // ==> not found 
} 

private function getFunctionName (callee:Function, parent:Object):String { 
    for each (var m:XML in describeType(parent)..method) { 
     if (parent[m.@name] == callee) return m.@name; 
    } 
    return "not found"; 
} 

Tenga en cuenta que esto no funcionaría cuando llame al someFunction() desde un constructor, porque el objeto no está completamente instanciado: describeType(this) en un constructor causaría un error de compilación.

Answer 2

Probablemente no podrá obtener el nombre de una función, porque no realmente tienen un "nombre" como tal. Al igual que sus variables no tienen nombres. Son solo indicadores de un objeto.

Obtener el nombre no tiene sentido, en parte por el siguiente ejemplo:

function foo():void 
{ 
    //get function name. 
} 
var bar:Function = foo; 
bar(); 

Una función es igual que cualquier otro objeto/variable. ¿Qué "nombre" encontraría esta función? "foo"? o "barra"? Tanto foo como la barra hacen referencia a la misma variable del tipo Function.

Una mejor manera de manejar esto sería pasar algo en la función como argumento:

function foo(myName:String):void 
{ 
    trace(myName); 
} 

Puede sin embargo, obtener una referencia a la función actual utilizando el arguments.callee :)

Answer 3

Lo acabo de hacer con un seguimiento de pila, que es lo que muestra el depurador de Flash Player cuando se produce un error no controlado. Aquí está mi aplicación:

function blah() 
{ 
    var e:Error = new Error(); 
    var s:String = e.getStackTrace(); 
    var functionName:String = s.slice(s.indexOf('/')+1, s.indexOf('(')); 
    trace(functionName); //blah 
} 

Usted va a necesitar para hacer el análisis de la cadena un poco más elegante, si quieres hacer de esto una función separada. Pero el nombre de la función definitivamente está en el rastro de la pila.

Editar: advertencia importante

El AS3 Lang Ref dice que el método getStackTrace sólo funciona en las versiones de depuración de Flash Player/AIR, y volverá null lo contrario. Entonces definitivamente esta no es una solución desplegable. Lo siento.

Answer 4

cuando necesitaba identificaciones para las funciones de aplicación para mi sistema de eventos no encontré una manera de acceder a una name de una función no anónimo pasa como argumento por lo que tenía que escribir un envoltorio que nada, excepto almacena la Function y su ID

Answer 5

para sacar esto adelante en ActionScript 2, que tenía que hacer recientemente con un poco de código heredado

function getFunctionName(func:Function):String 
{ 
    for(var prop in this) 
    { 
    if(this[prop] == func) 
    { 
     return prop; 
     break; 
    } 
    } 
} 

y utilizarlo algo como esto

trace(getFunctionName(arguments.callee));