¿puede una función actionscript encontrar su propio nombre?

Question

Dada la siguiente

function A(b:Function) { } 

Si la función A(), podemos determinar el nombre de la función que se está pasado como parámetro 'b'? ¿La respuesta difiere para AS2 y AS3?

Answer 1

¿El nombre? No, no puedes. Sin embargo, lo que puedes hacer es probar la referencia. Algo como esto:

function foo() 
{ 
} 

function bar() 
{ 
} 

function a(b : Function) 
{ 
    if(b == foo) 
    { 
     // b is the foo function. 
    } 
    else 
    if(b == bar) 
    { 
     // b is the bar function. 
    } 
} 

Answer 2

¿Está buscando simplemente una referencia para que pueda volver a llamar a la función? Si es así, intente configurar la función a una variable como referencia. var lastFunction: Function;

var func:Function = function test():void 
{ 
    trace('func has ran'); 
} 

function A(pFunc):void 
{ 
    pFunc(); 
    lastFunction = pFunc; 
} 
A(func); 

Ahora, si necesita hacer referencia a la última función ejecutada, puede hacerlo simplemente llamando a lastFunction.

No estoy seguro exactamente de lo que está tratando de hacer, pero quizás esto pueda ayudar.

Answer 3

utilizo el siguiente:

private function getFunctionName(e:Error):String { 
    var stackTrace:String = e.getStackTrace();  // entire stack trace 
    var startIndex:int = stackTrace.indexOf("at ");// start of first line 
    var endIndex:int = stackTrace.indexOf("()"); // end of function name 
    return stackTrace.substring(startIndex + 3, endIndex); 
} 

Uso:

private function on_applicationComplete(event:FlexEvent):void { 
    trace(getFunctionName(new Error()); 
} 

Salida: FlexAppName/on_applicationComplete()

Más información acerca de la técnica se puede encontrar en el sitio de Alex:

http://blogs.adobe.com/aharui/2007/10/debugging_tricks.html

Answer 4

No sé si ayuda, pero puede obtener una referencia a la persona que llama de la función que arguments (hasta donde yo sé, solo en ActionScript 3).

Answer 5

Heres una implementación simple

public function testFunction():void { 
     trace("this function name is " + FunctionUtils.getName()); //will output testFunction 
    } 

Y en un archivo llamado FunctionUtils pongo esto ...

/** Gets the name of the function which is calling */ 
    public static function getName():String { 
     var error:Error = new Error(); 
     var stackTrace:String = error.getStackTrace();  // entire stack trace 
     var startIndex:int = stackTrace.indexOf("at ", stackTrace.indexOf("at ") + 1); //start of second line 
     var endIndex:int = stackTrace.indexOf("()", startIndex); // end of function name 

     var lastLine:String = stackTrace.substring(startIndex + 3, endIndex); 
     var functionSeperatorIndex:int = lastLine.indexOf('/'); 

     var functionName:String = lastLine.substring(functionSeperatorIndex + 1, lastLine.length); 

     return functionName; 
    } 

Answer 6

He estado probando las soluciones sugeridas, pero me encontré con problemas con todos ellos en ciertos puntos. Principalmente debido a las limitaciones de los miembros dinámicos o fijos. Hice un poco de trabajo y combiné ambos enfoques. Eso sí, funciona solo para miembros públicamente visibles; en todos los demás casos, se devuelve null.

/** 
    * Returns the name of a function. The function must be <b>publicly</b> visible, 
    * otherwise nothing will be found and <code>null</code> returned.</br>Namespaces like 
    * <code>internal</code>, <code>protected</code>, <code>private</code>, etc. cannot 
    * be accessed by this method. 
    * 
    * @param f The function you want to get the name of. 
    * 
    * @return The name of the function or <code>null</code> if no match was found.</br> 
    *   In that case it is likely that the function is declared 
    *   in the <code>private</code> namespace. 
    **/ 
    public static function getFunctionName(f:Function):String 
    { 
     // get the object that contains the function (this of f) 
     var t:Object = getSavedThis(f); 

     // get all methods contained 
     var methods:XMLList = describeType(t)..method.@name; 

     for each (var m:String in methods) 
     { 
      // return the method name if the thisObject of f (t) 
      // has a property by that name 
      // that is not null (null = doesn't exist) and 
      // is strictly equal to the function we search the name of 
      if (t.hasOwnProperty(m) && t[m] != null && t[m] === f) return m;    
     } 
     // if we arrive here, we haven't found anything... 
     // maybe the function is declared in the private namespace? 
     return null;           
    } 

Answer 7

Use argumentos.destinatario de la llamada con toString() y match en general:

function foo(){return arguments.callee.toString().match(/\s\w+/).toString()} 

Referencias

• arguments callee method

• Tracing Function Arguments