Combinación programática de diapositivas de presentaciones múltiples en una sola presentación

Question

Necesito automatizar la creación de una presentación (ya sea OpenOffice o Powerpoint). La presentación debe tomar las dos primeras diapositivas de cada una de las presentaciones en un directorio determinado, y luego combinarlas en una sola presentación. Estoy confundido en cuanto a qué enfoque debo tomar para resolver esto. Cualquier puntero será apreciado.

Answer 1

Hablando de PowerPoint, se utiliza una macro de VBA para hacer el trabajo, algo así como

Sub Pull() 
Dim SrcDir As String, SrcFile As String 

    SrcDir = PickDir() 
    If SrcDir = "" Then Exit Sub 

    SrcFile = Dir(SrcDir & "\*.ppt") 

    Do While SrcFile <> "" 
     ImportFromPPT SrcDir + "\" + SrcFile, 1, 2 
     SrcFile = Dir() 
    Loop 

End Sub 

Selección de su directorio de origen puede utilizar esta función

Private Function PickDir() As String 
Dim FD As FileDialog 

    PickDir = "" 

    Set FD = Application.FileDialog(msoFileDialogFolderPicker) 
    With FD 
     .Title = "Pick a directory to work on" 
     .AllowMultiSelect = False 
     .Show 
     If .SelectedItems.Count <> 0 Then 
      PickDir = .SelectedItems(1) 
     End If 
    End With 

End Function 

ahora - el punto principal es insertar diapositivas de otro PPT mientras preservar el formato de origen. Esto es algo complicado, ya que el método PPT VBA InsertFromFile no sirve para nada. Microsoft nos dio un buen momento para resolverlo de la peor manera en innumerables sesiones de depuración de 20 horas :-) y necesita escribir un montón de código para hacerlo correctamente, mucho más complicado que usar el diálogo manualmente, en particular si su fuente de diapositivas se desvía de la diapositiva maestra de origen.

Si las de PPT están pegando a sus amos, se puede omitir de forma segura todo el código entre el ">>>>"

Private Sub ImportFromPPT(FileName As String, SlideFrom As Long, SlideTo As Long) 
Dim SrcPPT As Presentation, SrcSld As Slide, Idx As Long, SldCnt As Long 

    Set SrcPPT = Presentations.Open(FileName, , , msoFalse) 
    SldCnt = SrcPPT.Slides.Count 

    If SlideFrom > SldCnt Then Exit Sub 
    If SlideTo > SldCnt Then SlideTo = SldCnt 

    For Idx = SlideFrom To SlideTo Step 1 
     Set SrcSld = SrcPPT.Slides(Idx) 
     SrcSld.Copy 
     With ActivePresentation.Slides.Paste 
      .Design = SrcSld.Design 
      .ColorScheme = SrcSld.ColorScheme 
      ' if slide is not following its master (design, color scheme) 
      ' we must collect all bits & pieces from the slide itself 

      ' >>>>>>>>>>>>>>>>>>>> 

      If SrcSld.FollowMasterBackground = False Then 
       .FollowMasterBackground = False 
       .Background.Fill.Visible = SrcSld.Background.Fill.Visible 
       .Background.Fill.ForeColor = SrcSld.Background.Fill.ForeColor 
       .Background.Fill.BackColor = SrcSld.Background.Fill.BackColor 

       ' inspect the FillType object 
       Select Case SrcSld.Background.Fill.Type 
        Case Is = msoFillTextured 
         Select Case SrcSld.Background.Fill.TextureType 
         Case Is = msoTexturePreset 
          .Background.Fill.PresetTextured (SrcSld.Background.Fill.PresetTexture) 
         Case Is = msoTextureUserDefined 
         ' TextureName gives a filename w/o path 
         ' not implemented, see picture handling 
         End Select 

        Case Is = msoFillSolid 
         .Background.Fill.Transparency = 0# 
         .Background.Fill.Solid 

        Case Is = msoFillPicture 
         ' picture cannot be copied directly, need to export and re-import slide image 
         If SrcSld.Shapes.Count > 0 Then SrcSld.Shapes.Range.Visible = False 
         bMasterShapes = SrcSld.DisplayMasterShapes 
         SrcSld.DisplayMasterShapes = False 
         SrcSld.Export SrcPPT.Path & SrcSld.SlideID & ".png", "PNG" 

         .Background.Fill.UserPicture SrcPPT.Path & SrcSld.SlideID & ".png" 
         Kill (SrcPPT.Path & SrcSld.SlideID & ".png") 

         SrcSld.DisplayMasterShapes = bMasterShapes 
         If SrcSld.Shapes.Count > 0 Then SrcSld.Shapes.Range.Visible = True 

        Case Is = msoFillPatterned 
         .Background.Fill.Patterned (SrcSld.Background.Fill.Pattern) 

        Case Is = msoFillGradient 

         ' inspect gradient type 
         Select Case SrcSld.Background.Fill.GradientColorType 
         Case Is = msoGradientTwoColors 
          .Background.Fill.TwoColorGradient 
           SrcSld.Background.Fill.GradientStyle , _ 
           SrcSld.Background.Fill.GradientVariant 
         Case Is = msoGradientPresetColors 
          .Background.Fill.PresetGradient _ 
           SrcSld.Background.Fill.GradientStyle, _ 
           SrcSld.Background.Fill.GradientVariant, _ 
           SrcSld.Background.Fill.PresetGradientType 
         Case Is = msoGradientOneColor 
          .Background.Fill.OneColorGradient _ 
           SrcSld.Background.Fill.GradientStyle, _ 
           SrcSld.Background.Fill.GradientVariant, _ 
           SrcSld.Background.Fill.GradientDegree 
         End Select 

        Case Is = msoFillBackground 
         ' Only shapes - we shouldn't come here 
       End Select 
      End If 

      ' >>>>>>>>>>>>>>>>>>>> 

     End With 
    Next Idx 

End Sub 

El código no comprueba la fies protegidos con contraseña de sólo lectura o y voluntad chocar con ellos. También tenga cuidado de no ejecutar el archivo del recopilador. De lo contrario, debería funcionar. Debo admitir que no he revisado el código durante mucho tiempo ;-)

Answer 2

Puede google "unirse a powerpoint" para encontrar una herramienta útil para unir muchos ppts.

Answer 3

Me alegro de que @miked haya podido obtener lo que necesita.

Otro método a considerar, si usa .NET, se trata en this post