F # - ¿Puedo usar el nombre de tipo como una función que actúa como el constructor predeterminado?

Question

para crear una secuencia de mi clase,

type MyInt(i:int) = 
    member this.i = i 

[1;2;3] |> Seq.map(fun x->MyInt(x)) 

donde fun x->MyInt(x) parece ser redundante. Sería mejor si puedo escribir Seq.map(MyInt)

Pero no puedo. Una solución que puedo pensar es definir una función separada

let myint x = MyInt(x) 
[1;2;3] |> Seq.map(myint) 

¿Hay una manera mejor de hacer esto?

Answer 1

En resumen, no.

Los constructores de objetos no son funciones de primera clase en F #. Esta es una razón más para no usar clases, discriminado sindicatos es mejor utilizar aquí:

type myInt = MyInt of int 
let xs = [1;2;3] |> Seq.map MyInt 

Si no te gusta lambdas explícitas, la expresión de la secuencia se ve mejor en su ejemplo:

let xs = seq { for x in [1;2;3] -> MyInt x } 

Alternativamente , su solución es una buena solución.

Answer 2

Si hacks gratuitos no te molestan, se podría hacer:

///functionize constructor taking one arg 
let inline New< ^T, ^U when ^T : (static member ``.ctor`` : ^U -> ^T)> arg = 
    (^T : (static member ``.ctor`` : ^U -> ^T) arg) 

type MyInt(i: int) = 
    member x.i = i 

[0..9] |> List.map New<MyInt, _> 

EDIT: Como kvb señaló, una firma más simple (y menos hacky) se puede utilizar:

let inline New x = (^t : (new : ^u -> ^t) x) 

Tenga en cuenta que esto cambia el tipo args alrededor, por lo que se convierte en New<_, MyInt>.

Answer 3

Utilizo métodos estáticos para este propósito. La razón es que a veces el constructor de objetos necesita dos argumentos tomados de diferentes fuentes, y mi enfoque le permite utilizar List.map2:

type NumRange(value, range) = 
    static member Make aValue aRange = new NumRange(aValue, aRange) 

let result1 = List.map2 NumRange.Make values ranges 

Aplicación parcial no está prohibida, así:

let result2 = 
    values 
    |> List.map NumRange.Make 
    |> List.map2 id <| ranges 

si no le gusta usando id aquí, puede usar (fun x y -> x y) que es más legible.

Answer 4

Para dar una actualización sobre esto - F# 4.0 ha actualizado los constructores a funciones de primera clase, por lo que ahora se pueden usar en cualquier lugar donde se pueda utilizar una función o método.