¿cuál es la forma correcta de probar xs: decimal en XSL?

Question

Estoy tratando de mostrar información diferente dependiendo de los datos entrantes. Si es un número entero, quiero mostrar solo el número, si es un decimal, quiero usar el patrón 0.00 #. Ya, lo sé, un poco confuso, pero esa es la especificación de desarrollo. :>

Tengo el siguiente XSL para esta sección específica, pero no puedo ver a superar el XSL: cuando el mensaje de error de

"esperaba final de la expresión, que se encuentra número 'moldeable'. (SAVG) -> moldeable < - como xs: decimal"

<xsl:choose> 
    <xsl:when test="number(SAVG) > 0"> 
     <xsl:choose> 
      <xsl:when test="number(SAVG) castable as xs:decimal"> 
       <xsl:value-of select="format-number(SAVG, '###,###,##0.00#')"/> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:value-of select="format-number(SAVG, '###,###,##0.###')"/> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:when> 
    <xsl:when test="number(SAVG) = 0"> 
     <xsl:text disable-output-escaping="yes">&amp;lt;</xsl:text>1 
    </xsl:when> 
    <xsl:otherwise>N/A</xsl:otherwise> 
</xsl:choose> 

I intentado buscar/hurgando en busca de respuestas y he tratado de "instancia de", he intentado usar xsl: if , etc. pero parece que no puedo s para trabajar. Cualquier ayuda sería muy apreciada.

Gracias.

de:

Sí, estamos utilizando 1.0. Lo siento, soy nuevo en el procesamiento XSL, ¿cómo puedo pegar su XSL y la entrada para generar el html?

Answer 1

I. XSLT 1.0:

No hay xs: número entero y xs: decimal en el modelo de datos XPath 1.0 utilizados por XSLT 1.0.

Aquí es un fragmento de código que puede utilizar:

<xsl:choose> 
     <xsl:when test="not(floor(SAVG) = SAVG)"> 
      <xsl:value-of select="format-number(SAVG, '###,###,##0.00#')"/> 
     </xsl:when> 
     <xsl:otherwise> <!-- Integer value --> 
      <xsl:value-of select="SAVG"/> 
     </xsl:otherwise> 
    </xsl:choose> 

Ten en cuenta: Para probar si un valor numérico es un número entero, se utiliza la siguiente prueba:

floor($someNum) = $someNum 

---

Aquí hay una manera de hacerlo:

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema"> 
<xsl:output method="text"/> 

<xsl:template match="/"> 
    <xsl:sequence select= 
    "for $num in (3, 3.14) 
    return 
     if($num instance of xs:integer) 
     then ($num, ' is xs:integer', '&#xA;') 
     else if($num instance of xs:decimal) 
      then ($num, ' is xs:decimal', '&#xA;') 
      else ($num, ' is something else', '&#xA;') 
    "/> 
</xsl:template> 
</xsl:stylesheet> 

cuando se aplica esta transformación en cualquier documento XML (no se utiliza), el, resultado correcto querido se produce:

3 is xs:integer 
3.14 is xs:decimal 

O, usando la función format-number() como por su ejemplo :

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema"> 
<xsl:output method="text"/> 

<xsl:template match="/"> 
    <xsl:sequence select= 
    "for $num in (3, 3.14) 
    return 
     if($num instance of xs:integer) 
     then (format-number($num, '###,###,##0.###'), '&#xA;') 
     else if($num instance of xs:decimal) 
      then (format-number($num, '###,###,##0.00#'), '&#xA;') 
      else() 
    "/> 
</xsl:template> 
</xsl:stylesheet> 

produce:

3 
3.14 

Answer 2

Este XSLT 1.0 hoja de estilo:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="test"> 
     <xsl:choose> 
      <!-- Not number or number less than zero --> 
      <xsl:when test="0 > SVGA or number(SVGA) != SVGA"> 
       <xsl:text>N/A</xsl:text> 
      </xsl:when> 
      <!-- Number zero --> 
      <xsl:when test="SVGA = 0"> 
       <xsl:text>&lt;1</xsl:text> 
      </xsl:when> 
      <!-- Integer number --> 
      <xsl:when test="floor(SVGA) = SVGA"> 
       <xsl:value-of select="format-number(SVGA,'###,###,##0.###')"/> 
      </xsl:when> 
      <!-- Double number --> 
      <xsl:otherwise> 
       <xsl:value-of select="format-number(SVGA,'###,###,##0.00#')"/> 
      </xsl:otherwise> 
     </xsl:choose> 
     <xsl:text>&#xA;</xsl:text> 
    </xsl:template> 
</xsl:stylesheet> 

Con esta entrada:

<root> 
    <test> 
     <SVGA>0</SVGA> 
    </test> 
    <test> 
     <SVGA>12131</SVGA> 
    </test> 
    <test> 
     <SVGA>123.5654</SVGA> 
    </test> 
    <test> 
     <SVGA>-12.1</SVGA> 
    </test> 
    <test> 
     <SVGA>-7528</SVGA> 
    </test> 
    <test> 
     <SVGA>zero</SVGA> 
    </test> 
</root> 

de salida:

<1 
12,131 
123.565 
N/A 
N/A 
N/A 

Editar 3: Better pedido de prueba (además de la expresión de Dimitre), mejor tes t caso, muestra de entrada más cercana al interrogador.