Exportación de datos de archivos binarios (imágenes) de SQL a través de un procedimiento almacenado

Question

Estoy intentando exportar un número bastante grande de archivos de imagen, almacenada internamente en una base de datos SQL como datos binarios.

ser bastante nuevo en la escritura de procedimientos almacenados en SQL, me he encontrado con un par de guías muy útiles sobre cómo esto puede ser archivado, pero me parece que falta algo.

estoy corriendo SQL Server 2008 R2 a nivel local, y yo estoy tratando de escribir los archivos a una carpeta de mi unidad C: \.

Aquí es la parte buisness de lo que tengo hasta ahora:

BEGIN 
DECLARE @cmd VARCHAR(8000) 
DECLARE @result int 

DECLARE curExportBinaryDocs CURSOR FAST_FORWARD FOR 
SELECT 'BCP "SELECT Photograph_Data FROM [ALBSCH Trial].[dbo].[Photograph] WHERE Photograph_ID = ' 
    + CAST(Photograph_ID AS VARCHAR(500)) + '" queryout "' + @OutputFilePath 
    + CAST(Photograph_ID AS VARCHAR(500)) + '.jpg"' + ' -n -T' 
FROM dbo.Photograph 

OPEN curExportBinaryDocs 
FETCH NEXT FROM curExportBinaryDocs INTO @cmd 
WHILE @@FETCH_STATUS = 0 
    BEGIN 
    --PRINT @cmd 
    EXEC @result = xp_cmdshell @cmd   
    FETCH NEXT FROM curExportBinaryDocs INTO @cmd 
    END 
CLOSE curExportBinaryDocs 
DEALLOCATE curExportBinaryDocs 
END 

'@result' siempre está siendo puesto a '1' (fallidos) después de la llamada xp_cmdshell. Todos los nombres/campos de la tabla son correctos, así que sospecho que hay algo mal con mi llamada BCP, pero no estoy seguro de qué probar a continuación.

Cualquier ayuda o consejo sería muy bienvenido.

Answer 1

Bueno, en primer lugar .. (y lo siento por eso;)) DON "T .. utilizar cursores y lo siento por las tapas ...

uno de los más cosas más malo sobre cursores que están puede bloquear su mesa. lo que siempre hago para estos fines (y que es bastante rápido), yo uso un bucle for .. como esta

declare @totrow int 
     , @currow int 
     , @result int 
     , @nsql nvarchar(max) 

declare @sqlStatements table (
    Id int identity(1, 1) 
, SqlStatement varchar(max) 
) 
insert 
into @sqlStatements 
select 'QUERY PART' 
from table 

set @totrow = @@rowcount 
set @currow = 1 
while @totrow > 0 and @currow <= @totrow 
begin 
    select @nsql = SqlStatement 
    from @SqlStatements 
    where Id = @currow 

    exec @result = xp_cmdshell @nsql 

    set @currow = @currow + 1 
end 

para la siguiente parte, hace el proceso de SQL Server tiene suficiente permiso para escribe en la unidad c: también, mira en el panel de mensajes cuando ejecutas tu código, ¿quizás puedes encontrar algo allí?

Lo que también puede hacer, intente ejecutarlo manualmente. Solo obtenga un enunciado BCP y ejecútelo con xp_cmdshell. ¿Da algún error?

Answer 2

Aquí es mi último archivo de procedimiento de trabajo y el formato. No pude encontrar los detalles más precisos de los comandos BCP, las configuraciones de permisos y los formatos de archivos de formato en un solo lugar, así que tal vez esto sea útil para alguien.

CREATE PROCEDURE [dbo].[ImgExport] 
    @OutputFilePath VARCHAR(500) = 'C:\SQLTest\ ' 
AS 
BEGIN 
    DECLARE @totrow int 
    DECLARE @currow int 
    DECLARE @result int 
    DECLARE @nsql nvarchar(4000) 
    DECLARE @sqlStatements table (ID int IDENTITY(1, 1), SqlStatement varchar(max)) 

    INSERT 
    INTO @sqlStatements 
    SELECT 'BCP "SELECT Photograph_Data FROM [ALBSCH_Trial].[dbo].[Photograph] WHERE Photograph_ID = ''' 
    + CAST(Photograph_ID AS VARCHAR(500)) + '''" queryout ' + @OutputFilePath 
    + CAST(Photograph_ID AS VARCHAR(500)) + '.jpg -S localhost\SQLEXPRESS2008 -T -f C:\SQLTest\Images.fmt' 
    FROM dbo.Photograph 

    SET @totrow = @@ROWCOUNT 
    SET @currow = 1 
    WHILE @totrow > 0 and @currow <= @totrow 
    BEGIN 
     SELECT @nsql = SqlStatement 
     FROM @sqlStatements 
     WHERE ID = @currow 
     EXEC @result = xp_cmdshell @nsql 
     SET @currow = @currow + 1 
    END 
END  

archivo de formato:

9.0 
1 
1  SQLBINARY  0  0  "\t"  1  Photograph_Data         "" 

espero que ayude a alguien.