¿Es modificable la etiqueta CFDUMP?

Question

Con ColdFusion MX7 si encontramos una excepción, enviamos un correo electrónico al equipo de desarrollo que contiene volcados de los distintos ámbitos de datos, incluida la estructura del formulario.

Esto funciona muy bien para la depuración, excepto en el caso de un error cuando el usuario inicia sesión. Terminamos obteniendo la contraseña impresa.

Entonces, la pregunta es, ¿hay alguna manera de modificar el archivo CFDUMP para que filtre el valor de la contraseña fuera del objeto de formulario?

Naturalmente, podríamos ponerlo en el mismo código que envía el correo electrónico, sin embargo, sería ideal para ponerlo en el archivo CFDUMP para que no tengamos que preocuparnos de que aparezca en otros lugares.

He localizado el archivo CFDUMP y parece ser binario, así que supongo que no podemos hacerlo.

Answer 1

puede copiar el archivo dump.cfm a dumporiginal.cfm, y luego hacer una nueva dump.cfm que llama dumporiginal.cfm.

<!--- 
    So that it won't execute twice if you 
    have a closing slash (<cfdump ... />) 
---> 
<cfif thisTag.executionMode neq "start"> 
    <cfexit method="exitTag" /> 
</cfif> 


<!--- 
    defaults for optional attributes, taken from the docs 
    http://livedocs.adobe.com/coldfusion/8/htmldocs/Tags_d-e_08.html 
---> 
<cfparam name="attributes.expand" default="yes" /> 
<cfparam name="attributes.format" default="html" />  
<cfparam name="attributes.hide" default="all" />  
<cfparam name="attributes.keys" default="9999" />  
<cfparam name="attributes.label" default="" />  
<cfparam name="attributes.metainfo" default="yes" />  
<cfparam name="attributes.output" default="browser" />  
<cfparam name="attributes.show" default="all" />  
<cfparam name="attributes.showUDFs" default="yes" />  
<cfparam name="attributes.top" default="9999" />  

<!--- Hide the password, but store its value to put it back at the end ---> 
<cfif isStruct(attributes.var) and structKeyExists(attributes.var, 'password')> 
    <cfset originalPassword = attributes.var.password /> 
    <cfset attributes.var.password = "{hidden by customized cfdump}"/> 
</cfif> 

<!--- 
    Call the original cfdump. 
    Which attributes you pass depends on CF version. 
--->    
<cfswitch expression="#listFirst(server.coldfusion.productVersion)#"> 
<cfcase value="6"> 
    <cfdumporiginal 
     var = "#attributes.var#" 
     expand = "#attributes.expand#" 
     hide = "#attributes.hide#" 
     label = "#attributes.label#" 
     > 
</cfcase> 
<cfcase value="7"> 
    <cfdumporiginal 
     var = "#attributes.var#" 
     expand = "#attributes.expand#" 
     hide = "#attributes.hide#" 
     label = "#attributes.label#" 
     top = "#attributes.top#" 
     > 
</cfcase> 
<cfdefaultcase>  
    <cfdumporiginal 
     var = "#attributes.var#" 
     expand = "#attributes.expand#" 
     format = "#attributes.format#" 
     hide = "#attributes.hide#" 
     keys = "#attributes.keys#" 
     label = "#attributes.label#" 
     metainfo = "#attributes.metainfo#" 
     output = "#attributes.output#" 
     show = "#attributes.show#" 
     showUDFs = "#attributes.showUDFs#" 
     top = "#attributes.top#" 
     > 
</cfdefaultcase> 
</cfswitch> 

<!--- Restore the password, in case it's read after cfdump call ---> 
<cfif isDefined("originalPassword")> 
    <cfset attributes.var.password = originalPassword /> 
</cfif> 

Answer 2

No, no creo que haya una forma de modificar el comportamiento de <cfdump>. No puedo estar seguro, obviamente. Es pensable que existe tal truco, aunque no es necesariamente recomendable.

por qué no ir con un simple:

<cftry> 
    <cfset DoSomethingThatFails()> 

    <cfcatch> 
    <cfif StructKeyExists(FORM, "Password")> 
     <cfset FORM.Password = "***"> 
    </cfif> 
    <cfdump var="#FORM#"> 
    </cfcatch> 
</cftry> 

Answer 3

¿Es sólo la contraseña que es un problema de mostrar? Si es así, ¿quizás la solución es sal/hash la contraseña? Eso creo que es una buena práctica de todos modos.

http://blog.mxunit.org/2009/06/look-ma-no-password-secure-hashing-in.html

Answer 4

cfdump comenzó su vida como una etiqueta personalizada (CF_DUMP) allá por los días CF5. Siempre puede obtener el código de esa etiqueta personalizada, modificarla según sus necesidades y usarla en lugar de la etiqueta incorporada.