edificio Clojure de URL de partes constituyentes

Question

En Python que haría lo siguiente:

>>> q = urllib.urlencode({"q": "clojure url"}) 
>>> q 
'q=clojure+url' 

>>> url = "http://stackoverflow.com/search?" + q 
>>> url 
'http://stackoverflow.com/search?q=clojure+url' 

¿Cómo puedo hacer toda la codificación que ha hecho por mí anteriormente en Clojure? En otras palabras, ¿cómo puedo hacer algo parecido a lo siguiente:

=> (build-url "http://stackoverflow.com/search" {"q" "clojure url"}) 
"http://stackoverflow.com/search?q=clojure+url" 

Answer 1

Aquí está una manera:

user=> (import [java.net URLEncoder])              
java.net.URLEncoder 
user=> (str "http://stackoverflow.com/search?q=" (URLEncoder/encode "clojure url" "UTF-8")) 
"http://stackoverflow.com/search?q=clojure+url" 

que sé sin embargo, esto no es exactamente lo mismo que tu fragmento de Python. Consulte el siguiente puesto de la lista de correo Clojure para una respuesta más completa:

http://www.mail-archive.com/clojure@googlegroups.com/msg29338.html

El código de allí le permitirá hacer esto:

user=> (encode-params {"q" "clojure url"}) 
"q=clojure+url" 

Answer 2

Una solución sencilla usando str (Ings):

(def q (str "clojure+url")) 
(def url (str "http://stackoverflow.com/search?" q)) 

Answer 3

hay una función url-encode en Ring ring.util.codec espacio de nombres:

(ring.util.codec/url-encode "clojure url") 
; => "clojure+url" 

no estoy seguro si hay una función preenvasados ​​para convertir un mapa en un quer S String, pero tal vez esto podría hacer el trabajo:

(use '[ring.util.codec :only [url-encode]]) 

(defn make-query-string [m] 
    (->> (for [[k v] m] 
     (str (url-encode k) "=" (url-encode v))) 
     (interpose "&") 
     (apply str))) 

Un ejemplo:

user> (make-query-string {"q" "clojure url" "foo" "bar"}) 
"q=clojure+url&foo=bar" 

Todo lo que queda es la concatenación de los resultados en el extremo de una URL:

(defn build-url [url-base query-map] 
    (str url-base "?" (make-query-string query-map))) 

Parece para trabajar:

user> (build-url "http://stackoverflow.com/search" {"q" "clojure url"}) 
"http://stackoverflow.com/search?q=clojure+url" 

---

Actualización:

Tal vez una versión modificada podría hacer para una experiencia más Clojure ambiente. También maneja la codificación a través de un argumento opcional estilo anillo con utf-8 como predeterminado.

(defn make-query-string [m & [encoding]] 
    (let [s #(if (instance? clojure.lang.Named %) (name %) %) 
     enc (or encoding "UTF-8")] 
    (->> (for [[k v] m] 
      (str (url-encode (s k) enc) 
       "=" 
       (url-encode (str v) enc))) 
     (interpose "&") 
     (apply str)))) 

(defn build-url [url-base query-map & [encoding]] 
    (str url-base "?" (make-query-string query-map encoding))) 

Así que ahora podemos hacer

user> (build-url "http://example.com/q" {:foo 1}) 
"http://example.com/q?foo=1" 

Answer 4

clj-apache-http es bastante útil. Con él se pueden realizar las siguientes acciones:

user=> (require ['com.twinql.clojure.http :as 'http]) 
nil 
user=> (def q (http/encode-query {"q" "clojure url"})) 
#'user/q 
user=> (def url (str "http://stackoverflow.com/search?" q)) 
#'user/url 
user=> url 
"http://stackoverflow.com/search?q=clojure+url" 

Answer 5

Esto es el equivalente exacto de su sesión REPL pitón, utilizando clj-http.

user=> (require ['clj-http.client :as 'client]) 
nil 
user=> (str "http://stackoverflow.com/search?" 
user=*  (client/generate-query-string {"q" "clojure url"})) 
"http://stackoverflow.com/search?q=clojure+url" 

pero CLJ-http hace que sea aún más fácil:

user=> (client/get "http://stackoverflow.com/search?" 
user=*    {:query-params {"q" "clojure url"}}) 
... <a lot of output, omitted to protect the innocent>... 

asumiendo que se desea realizar una petición GET, es decir.