PL/SQL: ¿Cómo declaro las variables de sesión?

Question

¿Cómo declaro una variable de sesión en PL/SQL, una que persistirá solo durante la sesión, sin tener que almacenarla en la base de datos?

Answer 1

Crea una variable de nivel de paquete. Este es un ejemplo mínimo:

CREATE OR REPLACE PACKAGE my_package 
AS 
    FUNCTION get_a RETURN NUMBER; 
END my_package; 
/

CREATE OR REPLACE PACKAGE BODY my_package 
AS 
    a NUMBER(20); 

    FUNCTION get_a 
    RETURN NUMBER 
    IS 
    BEGIN 
     RETURN a; 
    END get_a; 
END my_package; 
/

Si usted hace esto, usted debe leer sobre (y manejar correctamente) ORA-04068 errores. Cada sesión de base de datos tendrá su propio valor para a. Puede probar esto con:

SELECT my_package.get_a FROM DUAL; 

Answer 2

Puede utilizar un 'contexto creado por el usuario' para almacenar datos compartidos a través de múltiples unidades en una sesión.

En primer lugar, crear un contexto:

CREATE CONTEXT SYS_CONTEXT ('userenv', 'current_schema')|| '_ctx' USING PKG_COMMON 

En segundo lugar, crear un paquete que administrar su contexto:

CREATE OR REPLACE PACKAGE PKG_COMMON 
IS 
    common_ctx_name CONSTANT VARCHAR2 (60) 
       := SYS_CONTEXT ('userenv', 'current_schema') 
        || '_ctx'; 

    FUNCTION fcn_get_context_name RETURN VARCHAR2; 
    PROCEDURE prc_set_context_value (var_name VARCHAR2, var_value NUMBER); 
END; 

CREATE OR REPLACE PACKAGE BODY PKG_COMMON 
IS 
    FUNCTION fcn_get_context_name 
     RETURN VARCHAR2 
    IS 
    BEGIN 
     RETURN common_ctx_name; 
    END; 

    PROCEDURE prc_set_context_value (var_name VARCHAR2, var_value NUMBER) 
    IS 
    BEGIN 
     DBMS_SESSION.set_context (common_ctx_name, var_name, var_value); 
    END; 
END; 

El prc_set_context_value puede ser más avanzada, eso es sólo un ejemplo. Con el contexto y el paquete creado, puede comenzar a usarlos. establecer una variable de contexto mediante una llamada a procedimiento

begin 
    PKG_COMMON.prc_set_context_value('MyVariable', 9000) 
end; 

y utilizarlo en cualquier lugar - cualquier procedimiento, paquete, función o evento una vista.

CREATE VIEW V_TEST AS 
    SELECT ID, LOGIN, NAME 
    FROM USERS 
    WHERE ROLE_ID = SYS_CONTEXT(PKG_COMMON.FCN_GET_CONTEXT_NAME, 'MyVariable') 

Para más información ver http://www.psoug.org/reference/sys_context.html