Alcance de la variable en XSLT

Question

Tengo un problema al tratar de determinar var scoping en xslt. Lo que realmente quiero hacer es ignorar las etiquetas de 'viaje' que tienen un 'tourcode' repetido.

XML de ejemplo: Procesador

<trip> 
<tourcode>X1</tourcode> 
<result>Budapest</result> 
</trip> 
<trip> 
<tourcode>X1</tourcode> 
<result>Budapest</result> 
</trip> 
<trip> 
<tourcode>X1</tourcode> 
<result>Budapest</result> 
</trip> 
<trip> 
<tourcode>Y1</tourcode> 
<result>london</result> 
</trip> 
<trip> 
<tourcode>Y1</tourcode> 
<result>london</result> 
</trip> 
<trip> 
<tourcode>Z1</tourcode> 
<result>Rome</result> 
</trip> 

XSLT:

<xsl:for-each select="trip">  
    <xsl:if test="not(tourcode = $temp)"> 
     <xsl:variable name="temp" select="tour"/> 
     // Do Something (Print result!) 
    </xsl:if> 
</xsl:for-each> 

salida deseada: Budapest Londres Roma

Answer 1

salida deseada: Budapest Londres Roma

lo que está después es agrupar la producción en nombre de la ciudad. Hay dos formas comunes de hacer esto en XSLT.

Uno de ellos es la siguiente:

<xsl:template match="/allTrips"> 
    <xsl:apply-templates select="trip" /> 
</xsl:template> 

<xsl:template match="trip"> 
    <!-- test if there is any preceding <trip> with the same <result> --> 
    <xsl:if test="not(preceding-sibling::trip[result = current()/result])"> 
    <!-- if there is not, output the current <result> --> 
    <xsl:copy-of select="result" /> 
    </xsl:if> 
</xsl:template> 

Y el otro se llama agrupación Muenchian y @Rubens Farías acaba de publicar una respuesta que muestra cómo hacerlo.

Answer 2

Usted no puede cambian las variables en XSLT.

Debe considerarlo más como functional programming en lugar de procedimiento, porque XSLT es un lenguaje funcional. Piense en el ámbito de las variables en algo como esto pseudocódigo:

variable temp = 5 
call function other() 
print temp 

define function other() 
    variable temp = 10 
    print temp 

¿Qué espera que la salida sea? Debe ser 10 5, no 10 10, porque temp dentro de la función other no es la misma variable que temp fuera de esa función.

Pasa lo mismo en XSLT. Las variables, una vez creadas, no se pueden redefinir porque son de escritura única, leídas, muchas variables por diseño.

Si desea realizar el valor de una variable definida de forma condicional, tendrá que definir la variable condicional, así:

<xsl:variable name="temp"> 
    <xsl:choose> 
    <xsl:when test="not(tourcode = 'a')"> 
     <xsl:text>b</xsl:text> 
    </xsl:when> 
    <xsl:otherwise> 
     <xsl:text>a</xsl:text> 
    </xsl:otherwise> 
    </xsl:choose> 
</xsl:variable> 
<xsl:if test="$temp = 'b'"> 
    <!-- Do something --> 
</xsl:if> 

La variable sólo se define en un solo lugar, pero su valor es condicional. Ahora que el valor de temp está establecido, no puede redefinirse más tarde. En la programación funcional, las variables son más como parámetros de solo lectura en el sentido de que se pueden establecer pero no se pueden cambiar más adelante. Debe comprender esto correctamente para usar variables en cualquier lenguaje de programación funcional.

Answer 3

Prueba esto:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:key name="trip" match="trip" use="result" /> 

    <xsl:template match="/trips"> 

    <xsl:for-each select="trip[count(. | key('trip', result)[1]) = 1]"> 
     <xsl:if test="position() != 1">, </xsl:if> 
     <xsl:value-of select="result"/> 
    </xsl:for-each> 

    </xsl:template> 
</xsl:stylesheet>