VBA de Excel: hacer que parte de la cadena negrita

Question

tengo celdas de Excel que contienen entradas como esta:

name/A/date 
name/B/date 
name/C/date 

contenido celular se muestran en varias líneas en la misma celda. Me gustaría hacer solo "nombre" en negrita para todas las entradas. He grabado una macro y creo que la solución debe ser algo como esto:

ActiveCell.FormulaR1C1 = "name/A/date" & Chr(10) & "name/B/date" & Chr(10) & "name/C/date" 
With ActiveCell.Characters(Start:=25, Length:=4).Font 
    .FontStyle = "Bold" 
End With 

Lo que no sé es cómo obtener el valor de inicio y la duración de cada entrada. Alguien tiene una idea?

Answer 1

tenerlo ahora:

lngPos = InStr(ActiveCell.Value, "/") 
With ActiveCell.Characters(Start:=1, Length:=lngPos - 1).Font 
    .FontStyle = "Bold" 
End With 

Answer 2

Inspirado por diversas investigaciones en los últimos días:

Dim totalVals, startPos(), endPos(), i, j, strLen As Long 
Dim currLine As String 

' Split the cell value (a string) in lines of text 
splitVals = Split(ActiveCell.Value, Chr(10)) 

' This is how many lines you have 
totalVals = UBound(splitVals) 

' For each line, you'll have a character where you want the string to start being BOLD 
ReDim startPos(0 To totalVals) 

' And one character where you'll want it to stop 
ReDim endPos(0 To totalVals) 

' The value of the current line (before we loop on ActiveCell.Value) is empty 
currLine = "" 

For i = 0 To totalVals ' For each line... 

    ' Length of the string currently treated by our code : 0 if no treatment yet... 
    strLen = Len(currLine) 

    ' Here we parse and rewrite the current ActiveCell.Value, line by line, in a string 
    currLine = currLine & IIf(currLine = "", "", Chr(10)) & splitVals(i) 

    ' At each step (= each line), we define the start position of the bold part 
    ' Here, it is the 1st character of the new line, i.e. strLen + 1 
    startPos(i) = strLen + 1 

    ' At each step (= each line), we define the end position of the bold part 
    ' Here, it is just before the 1st "/" in the current line (hence we start from strLen) 
    endPos(i) = InStr(IIf(strLen = 0, 1, strLen), currLine, "/") 

Next i 

' Then we use the calculated positions to get the characters in bold 
For j = 0 To UBound(startPos) 
    ActiveCell.Characters(startPos(j), endPos(j) - startPos(j)).Font.FontStyle = "Bold" 
Next j 

Podría ser un poco exagerado, buti lo he probado y funciona como un encanto. ¡Espero que esto ayude!