¿Cómo aplico plantillas a cada nodo seleccionado en un for-each?

Question

Sé que me falta algo aquí. En la transformación XSLT a continuación, el resultado real no coincide con el resultado deseado.

Dentro del for-each, deseo aplicar la plantilla match="track" a cada elemento track seleccionado. Si entendí XSLT correctamente, con la configuración actual, solo los nodos secundarios de cada elemento track seleccionado se comparan con las plantillas, no con los elementos track.

¿Cómo puedo hacer que los elementos track pasen por la plantilla como lo desee? ¿Debo reconsiderar mi enfoque completo?

Nota: La transformación se ejecuta con PHP. Las declaraciones XML se han omitido por brevedad. Documento

XML:

<album> 
    <title>Grave Dancers Union</title> 
    <track id="shove">Somebody To Shove</track> 
    <track id="gold">Black Gold</track> 
    <track id="train">Runaway Train</track> 
    <producer>Michael Beinhorn</producer> 
</album> 

hoja de estilo XSL:

<xsl:stylesheet version="1.1" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="/album"> 
     <ol> 
      <xsl:for-each select="track"> 
       <li><xsl:apply-templates/></li> 
      </xsl:for-each> 
     </ol> 
    </xsl:template> 

    <xsl:template match="track"> 
     <a href="{@id}"><xsl:apply-templates/></a> 
    </xsl:template> 
</xsl:stylesheet> 

Resultado:

<ol> 
    <li>Somebody To Shove</li> 
    <li>Black Gold</li> 
    <li>Runaway Train</li> 
</ol> 

Resultado deseado:

<ol> 
    <li><a href="shove">Somebody To Shove</a></li> 
    <li><a href="gold">Black Gold</a></li> 
    <li><a href="train">Runaway Train</a></li> 
</ol> 

Answer 1

Estoy de acuerdo con 'ndim' que probablemente deba reestructurar su XSLT para eliminar el bucle xsl: for-each.

Como alternativa, puede modificar el XSL: apply-templates para seleccionar el nodo pista actual dentro del xsl: for-each

<xsl:for-each select="track"> 
    <li> 
     <xsl:apply-templates select="." /> 
    </li> 
</xsl:for-each> 

Mantener el XSL: Con fines de cada uno de ellos, al menos, le permitirá ordenar las pistas en otro orden, si lo desea.

Answer 2

me gustaría reestructurar un poco (si es que no es necesario la clasificación del enfoque for-each hace que sea posible):

<xsl:template match="/album"> 
    <ol> 
    <xsl:apply-templates select="track"/> 
    </ol> 
</xsl:template> 

<xsl:template match="track"> 
    <li><a href="{@id}"><xsl:apply-templates/></a></li> 
<xsl:template> 

Esto se ve más corto y más al punto , EN MI HUMILDE OPINIÓN.

pienso que su

<xsl:for-each select="track"> 
     <li><xsl:apply-templates/></li> 
    </xsl:for-each> 

paseos a través de todos los elementos de la vía con el for-each, y luego aplica las reglas predeterminadas a sus descendientes. Por lo tanto, el contenido de for-each tiene el mismo nodo de contexto que la plantilla match="track" y, por lo tanto, la plantilla match="track" nunca coincide.

Si realmente desea utilizar el for-each de esa manera, tendrá que cambiar ninguna de las dos cosas siguientes en su enfoque:

1. Añadir un atributo name="track" a la plantilla match="track", y luego usar <xsl:call-template/> desde dentro de for-each (mi idea, y peor que Tim C)
2. Use la solución Tim C usando <xsl:apply-templates select="."/>. Esto tiene la ventaja de evitar nombrar y mantener la posibilidad de ordenar las pistas.