¿Qué tipo de datos es adecuado para manejar datos binarios en el método ActiveX?

Question

Estoy escribiendo un control ActiveX para mi amigo, que debe encapsular las rutinas de encriptación. Se usará desde VB6 principalmente. ¿Qué tipo de datos debo elegir para datos binarios, como la clave de cifrado, el vector de inicialización, los datos de entrada y salida para que sea conveniente para mi amigo usarlo desde VB6?

Estoy usando Delphi 7 para escribir este ActiveX, si eso es importante. Una opción es usar cadenas hexadecimales. ¿Cuál puede ser el otro?

Answer 1

VB6 Datos binarios almacenados en variables Byte y matrices.

Dim arrData() As Byte 

aplicación VB6 debe pasar esa variable a su Delphi COM como OleVariant. Delphi COM puede convertir VarArray a TStream y viceversa:

procedure VariantToStream(const v :OleVariant; Stream: TStream); 
var 
    p : pointer; 
    lo, hi, size: Integer; 
begin 
    lo := VarArrayLowBound(v, 1); 
    hi := VarArrayHighBound (v, 1); 
    if (lo >= 0) and (hi >= 0) then 
    begin 
    size := hi - lo + 1; 
    p := VarArrayLock (v); 
    try 
     Stream.WriteBuffer (p^, size); 
    finally 
     VarArrayUnlock (v); 
    end; 
    end; 
end; 

procedure StreamToVariant(Stream: TStream; var v: OleVariant); 
var 
    p : pointer; 
    size: Integer; 
begin 
    size := Stream.Size - Stream.Position; 
    v := VarArrayCreate ([0, size - 1], varByte); 
    if size > 0 then 
    begin 
    p := VarArrayLock (v); 
    try 
     Stream.ReadBuffer (p^, size); 
    finally 
     VarArrayUnlock (v); 
    end; 
    end; 
end; 

uso en la unidad CoClass:

// HRESULT _stdcall BinaryTest([in] VARIANT BinIn, [out, retval] VARIANT * BinOut); 
function TMyComClass.BinaryTest(BinIn: OleVariant): OleVariant; safecall; 
var 
    Stream: TMemoryStream; 
begin 
    Stream := TMemoryStream.Create; 
    try 
    VariantToStream(BinIn, Stream); 
    Stream.Position := 0; 

    // do something with Stream ... 

    // ... and return some Binary data to caller (* BinOut) 
    Stream.Position := 0; 
    StreamToVariant(Stream, Result); 
    finally 
    Stream.Free; 
    end; 
end; 

---

Este es el enfoque más común el uso de SAFEARRAY de bytes con los datos binarios a través Automatización COM.
Rellenar los datos en un BSTR (Hex strings, Base64 Encoding etc ..) suena un poco feo para mí y parece más un hack.