Perl: Use s/(replace) y return new string

Question

En Perl, el operador s/ se usa para reemplazar partes de una cadena. Ahora s/ alterará su parámetro (la cadena) en su lugar. Sin embargo, quisiera reemplazar partes de una cadena se acaben imprimirlo, como en

print "bla: ", replace("a","b",$myvar),"\n"; 

¿Existe tal replace función en Perl, o alguna otra forma de hacerlo? s/ no funcionará directamente en este caso, y me gustaría evitar el uso de una variable auxiliar. ¿Hay alguna forma de hacer esto en línea?

Answer 1

No comprobado:

require 5.013002; 
print "bla: ", $myvar =~ s/a/b/r, "\n"; 

Ver perl5132delta:

El operador de sustitución ahora es compatible con una opción/r que copia la variable de entrada, lleva a cabo la sustitución en la copia y devuelve el resultado. El original permanece sin modificaciones.

my $old = 'cat'; 
my $new = $old =~ s/cat/dog/r; 
# $old is 'cat' and $new is 'dog' 

Answer 2

En Perl 5.14 y más tarde se puede utilizar la opción /r con el operador de sustitución para realizar non-destructive substitution:

print "bla: ", $myvar =~ s/a/b/r, "\n"; 

Alternativamente, se puede utilizar un bloque de do() con una variable léxica temporal, por ejemplo:

print "bla: ", do { (my $tmp = $myvar) =~ s/a/b/; $tmp }, "\n"; 

Answer 3

print "bla: ", $_, "\n" if ($_ = $myvar) =~ s/a/b/g or 1; 

Answer 4

Si realmente desea, puede hacer su propio, pero yo no porque tiene mucha más funcionalidad con s/// ... se podría construir esa funcionalidad en su función, pero ¿por qué recrear algo que ya existe?

#!/usr/bin/perl -w  

use strict;  

    main(); 

    sub main{  
     my $foo = "blahblahblah";   
     print '$foo: ' , replace("lah","ar",$foo) , "\n"; #$foo: barbarbar 

    }   

    sub replace { 
     my ($from,$to,$string) = @_; 
     $string =~s/$from/$to/ig;       #case-insensitive/global (all occurrences) 

     return $string; 
    } 

Answer 5

print "bla: ", $myvar =~ tr{a}{b},"\n";