¿Hay una expresión regular en Perl para encontrar la extensión de un archivo?

Question

¿Hay una expresión regular en Perl para encontrar la extensión de un archivo? Por ejemplo, si tengo "test.exe", ¿cómo obtendré el ".exe"?

Answer 1

my $file = "test.exe"; 

# Match a dot, followed by any number of non-dots until the 
# end of the line. 
my ($ext) = $file =~ /(\.[^.]+)$/; 

print "$ext\n"; 

Answer 2

\.[^\.]*$ 

Esto le daría todo lo que tras el último punto (incluyendo el punto en sí) hasta el final de la cadena.

Answer 3

Usted podría utilizar File::Basename para extraer una extensión de archivo arbitrario:

use strict; 
use warnings; 
use File::Basename; 
my $ext = (fileparse("/foo/bar/baz.exe", qr/\.[^.]*/))[2]; 
print "$ext"; 

Answer 4

uso de archivos :: Nombre base

use File::Basename; 
    ($name,$path,$suffix) = fileparse("test.exe.bat",qr"\..[^.]*$"); 
    print $suffix; 

Answer 5

Aquí se trata de una expresión regular para que coincida con el patrón n archivo de extensión de nivel (por ejemplo, .tar.gz o .tar.bz2).

((\.[^.\s]+)+)$ 

Ejemplo:

#!/usr/bin/perl 

my $file1 = "filename.tar.gz.bak"; 
my ($ext1) = $file1 =~ /((\.[^.\s]+)+)$/; 

my $file2 = "filename.exe"; 
my ($ext2) = $file2 =~ /((\.[^.\s]+)+)$/; 

my $file3 = "filename. exe"; 
my ($ext3) = $file3 =~ /((\.[^.\s]+)+)$/; 

my $file4 = "filename.............doc"; 
my ($ext4) = $file4 =~ /((\.[^.\s]+)+)$/; 

print "1) $ext1\n"; # prints "1) .tar.gz.bak" 
print "2) $ext2\n"; # prints "2) .exe" 
print "3) $ext3\n"; # prints "3) " 
print "4) $ext4\n"; # prints "4) .doc"