¿Cómo puedo encontrar todas las coincidencias con una expresión regular en Perl?

Question

tengo el texto en la forma:

Name=Value1 
Name=Value2 
Name=Value3 

Utilizando Perl, me gustaría coincidir /Name=(.+?)/ cada vez que aparece y extraer el y empujarlo hacia una matriz (+.?). Sé que puedo usar $1 para obtener el texto que necesito y puedo usar =~ para realizar la comparación de expresiones regulares, pero no sé cómo obtener todas las coincidencias.

Answer 1

A m//g en la lista context devuelve todas las coincidencias capturadas.

#!/usr/bin/perl 

use strict; use warnings; 

my $str = <<EO_STR; 
Name=Value1 
Name=Value2 
Name=Value3 
EO_STR 

my @matches = $str =~ /=(\w+)/g; 
# or my @matches = $str =~ /=([^\n]+)/g; 
# or my @matches = $str =~ /=(.+)$/mg; 
# depending on what you want to capture 

print "@matches\n"; 

Sin embargo, parece que está analizando un archivo de configuración de estilo INI. En ese caso, recomendaré Config::Std.

Answer 2

my @values; 
while(<DATA>){ 
    chomp; 
    push @values, /Name=(.+?)$/; 
} 
print join " " => @values,"\n"; 

__DATA__ 
Name=Value1 
Name=Value2 
Name=Value3 

Answer 3

En lugar de utilizar una expresión regular es posible que prefiera probar un motor de la gramática como:

• Parse::RecDescent
• Regexp::Grammars

me he dado un fragmento de una respuesta antes de Parse::ResDescent en lo. Sin embargo, Regexp :: Grammars se ve muy interesante y está influenciado por Perl6 rules & grammars.

Así que pensé que tendría una grieta en Regexp :: Gramáticas ;-)

use strict; 
use warnings; 
use 5.010; 

my $text = q{ 
Name=Value1 
Name = Value2 
Name=Value3 
}; 

my $grammar = do { 
    use Regexp::Grammars; 
    qr{ 
     <[VariableDeclare]>* 

     <rule: VariableDeclare> 
      <Var> \= <Value> 

     <token: Var> Name 

     <rule: Value> <MATCH= ([\w]+) > 
    }xms; 
}; 


if ($text =~ $grammar) { 
    my @Name_values = map { $_->{Value} } @{ $/{VariableDeclare} }; 
    say "@Name_values"; 
} 

Las salidas de código anteriores Value1 Value2 Value3.

¡Muy bonito! La única salvedad es que requiere Perl 5.10 y que puede ser excesiva para el ejemplo que ya ha proporcionado ;-)

/I3az/

Answer 4

uso de un módulo Config:: para leer los datos de configuración. Para algo simple como eso, podría alcanzar el ConfigReader::Simple. Es bueno mantenerse alejado de las malas hierbas siempre que sea posible.

Answer 5

Lo siguiente dará todas las coincidencias con la expresión regular en una matriz.

push (@matches,$&) while($string =~ /=(.+)$/g);