Cómo cambiar el nombre de la base de datos física Archivos

Question

he utilizado tsql separar una base de datos de la siguiente manera:

EXEC sp_detach_db @dbname = 'my_db' 

que a continuación hizo uso de PHP para cambiar el nombre de los archivos físicos. ¡Pude cambiar el nombre del archivo mdf pero no el archivo ldf! ¡Incluso probé un comando dos REN pero eso tampoco funcionó para el archivo ldf!

Quería preguntar, ¿hay algo especial acerca de los archivos de registro físico que permiten que no se renombre?

¿Hay una mejor manera de hacerlo?

Gracias a todos

Answer 1

Puede hacerlo mediante una declaración ALTER DATABASE - como esto:

ALTER DATABASE (your database) 
    MODIFY FILE (NAME = logical_file_name, 
       FILENAME = ' new_path/os_file_name ') 

tiene que modificar cada archivo por separado, por ejemplo, si tiene varios archivos de datos, debe modificar cada uno de ellos.

Para obtener más información, consulte el Technet documentation on this topic.

Answer 2

El comando "ALTER DATABASE (su base de datos) MODIFY FILE" solo cambiará el nombre de los nombres lógicos. Este post muestra cómo utilizar xp_cmdshell para cambiar el nombre también los archivos físicos: http://www.mssqltips.com/sqlservertip/1891/best-practice-for-renaming-a-sql-server-database/

Tenga en cuenta lo siguiente: 1.
xp_cmdshell se ejecuta bajo el usuario el que el proceso de SQL Server se ejecuta como, y podría no tener el sistema de archivos permisos necesarios para cambiar el nombre de los archivos de base de
2. Por razones de seguridad, no olvide desactivar xp_xmdshell

el siguiente es un ejemplo de cómo el cambio de nombre se puede hacer en base a la entrada en el blog mencionado. Reemplazará la base de datos MyDB con la base de datos NewMyDB. El MyDB original (renombrado a MyDB_OLD) quedará separado.

-- Enable xp_cmdshell: 
sp_configure 'show advanced options', 1 
RECONFIGURE WITH OVERRIDE 
GO 
sp_configure 'xp_cmdshell', 1 
RECONFIGURE WITH OVERRIDE 
GO 

-- Get physical file names: 
declare @MyDBOriginalFileName nvarchar(300) = (select physical_name FROM sys.master_files where name = 'MyDB') 
declare @MyDBLogOriginalFileName nvarchar(300) = (select physical_name FROM sys.master_files where name = 'MyDB_log') 
declare @NewMyDBOriginalFileName nvarchar(300) = (select physical_name FROM sys.master_files where name = 'NewMyDB') 
declare @NewMyDBLogOriginalFileName nvarchar(300) = (select physical_name FROM sys.master_files where name = 'NewMyDB_log') 
declare @Command nvarchar(500) 
declare @Sql nvarchar(2000) 

IF (EXISTS (select * from sys.databases where name = 'NewMyDB') 
AND EXISTS (select * from sys.databases where name = 'MyDB')) 
BEGIN 
    USE master 

    ALTER DATABASE MyDB SET SINGLE_USER WITH ROLLBACK IMMEDIATE 
    ALTER DATABASE NewMyDB SET SINGLE_USER WITH ROLLBACK IMMEDIATE 

     -- Set new database name 
     ALTER DATABASE MyDB MODIFY NAME = MyDB_OLD 
     ALTER DATABASE NewMyDB MODIFY NAME = MyDB 

     -- Update logical names 
     ALTER DATABASE MyDB_OLD MODIFY FILE (NAME=N'MyDB', NEWNAME=N'MyDB_OLD') 
     ALTER DATABASE [MyDB] MODIFY FILE (NAME=N'NewMyDB', NEWNAME=N'MyDB') 

     EXEC master.dbo.sp_detach_db @dbname = N'MyDB_Old' 
     EXEC master.dbo.sp_detach_db @dbname = N'MyDB' 

     -- Rename physical files 
     SET @Command = 'RENAME "' + @MyDBOriginalFileName + '" "MyDB_OLD.mdf"'; PRINT @Command 
     EXEC xp_cmdshell @Command 
     SET @Command = 'RENAME "' + @MyDBLogOriginalFileName + '" "MyDB_OLD_log.mdf"'; PRINT @Command 
     EXEC xp_cmdshell @Command 
     SET @Command = 'RENAME "' + @NewMyDBOriginalFileName + '" "MyDB.mdf"'; PRINT @Command 
     EXEC xp_cmdshell @Command 
     SET @Command = 'RENAME "' + @NewMyDBLogOriginalFileName + '" "MyDB_log.mdf"'; PRINT @Command 
     EXEC xp_cmdshell @Command 

     -- Attach with new file names 
     declare @NewMyDBFileNameAfterRename nvarchar(300) = replace(@NewMyDBOriginalFileName, 'NewMyDB', 'MyDB') 
     declare @NewMyDBLogFileNameAfterRename nvarchar(300) = replace(@NewMyDBOriginalFileName, 'NewMyDB_log', 'MyDB_log') 
     SET @Sql = 'CREATE DATABASE MyDB ON (FILENAME = ''' + @NewMyDBFileNameAfterRename + '''), (FILENAME = ''' + @NewMyDBLogFileNameAfterRename + ''') FOR ATTACH' 
     PRINT @Sql 
     EXEC (@Sql) 

    ALTER DATABASE MyDB SET MULTI_USER 

END 

-- Disable xp_cmdshell for security reasons: 
GO 
sp_configure 'show advanced options', 1 
RECONFIGURE WITH OVERRIDE 
GO 
sp_configure 'xp_cmdshell', 0 
RECONFIGURE WITH OVERRIDE 
GO 

Answer 3

Separar la base de datos, renombrar los archivos, adjuntarla de nuevo.

Answer 4

La forma más sencilla de cambiar el nombre de SQL server physical database files es:

1. abierto y conectar con el SQL server en la base de datos que quería cambiar el nombre se encuentra.
2. Ejecute la siguiente secuencia de comandos en la ventana de consulta para cambiar los nombres físicos y lógicos. Recuerde reemplazar todo el "OldDatabaseName" con el nuevo nombre de la base de datos ("NewDatabaseName") al que desea cambiar su nombre.Reemplazar todo NewDatabaseName con el nuevo nombre que desea establecer para su base de datos

use OldDatabaseName

ALTER DATABASE OldDabaseName MODIFY FILE (NAME='OldDatabaseName', FILENAME='C:\Program Files\Microsoft SQL Server\MSSQL10_50.MSSQLSERVER\MSSQL\DATA\NewDatabaseName.mdf'); 

ALTER DATABASE OldDatabaseName MODIFY FILE (NAME='OldDatabaseName_log', FILENAME='C:\Program Files\Microsoft SQL Server\MSSQL10_50.MSSQLSERVER\MSSQL\DATA\NewDatabaseName_log.ldf'); 

ALTER DATABASE OldDatabaseName MODIFY FILE (NAME = OldDatabaseName, NEWNAME = NewDatabaseName); 
ALTER DATABASE OldDatabaseName MODIFY FILE (NAME = OldDatabaseName_log, NEWNAME = NewDatabaseName_log); 

3. y haga clic en el OldDatabaseName, seleccione Tasks y luego elija Take Offline

4. Vaya a la ubicación (C:\Program Files\Microsoft SQL Server\MSSQL10_50.MSSQLSERVER\MSSQL\DATA\...) donde se encuentran los archivos físicos y cámbiele el nombre al NewDatabaseName que especificó en número 2. Recuerde verificar la ruta absoluta de estos archivos para usar en su computadora.
5. Volver a Microsoft SQL Server Management Studio. Haga clic con el botón derecho en OldDatabaseName, seleccione Tasks y luego elija Bring Online.
6. Por último, continúe y cambie el nombre de su OldDatabaseName al NewDatabaseName. Has terminado :-)