Cómo dividir la cadena en delphi

Question

Solo necesito dividir una cadena como: "STANS", "Payment, chk#1", ,1210.000 en una matriz basada en ,. El resultado en la lista cadena sería

STANS 
Payment, chk#1 

1210.000 

Answer 1

Crear una TStringList y asignar su cadena separada por comas de StringList.CommaText. Esto analiza su entrada y devuelve las cadenas divididas como los elementos de la lista de cadenas.

StringList.CommaText := '"STANS", "Payment, chk# 1", ,1210.000'; 
//StringList[0]='STANS' 
//StringList[1]='Payment, chk# 1' 
//etc. 

Answer 2

escribí esta función y funciona perfecto para mí en Delphi 2007

function ParseCSV(const S: string; ADelimiter: Char = ','; AQuoteChar: Char = '"'): TStrings; 
type 
    TState = (sNone, sBegin, sEnd); 
var 
    I: Integer; 
    state: TState; 
    token: string; 

    procedure AddToResult; 
    begin 
     if (token <> '') and (token[1] = AQuoteChar) then 
     begin 
     Delete(token, 1, 1); 
     Delete(token, Length(token), 1); 
     end; 
     Result.Add(token); 
     token := ''; 
    end; 

begin 
    Result := TstringList.Create; 
    state := sNone; 
    token := ''; 
    I := 1; 
    while I <= Length(S) do 
    begin 
    case state of 
     sNone: 
     begin 
      if S[I] = ADelimiter then 
      begin 
      token := ''; 
      AddToResult; 
      Inc(I); 
      Continue; 
      end; 

      state := sBegin; 
     end; 
     sBegin: 
     begin 
      if S[I] = ADelimiter then 
      if (token <> '') and (token[1] <> AQuoteChar) then 
      begin 
       state := sEnd; 
       Continue; 
      end; 

      if S[I] = AQuoteChar then 
      if (I = Length(S)) or (S[I + 1] = ADelimiter) then 
       state := sEnd; 
     end; 
     sEnd: 
     begin 
      state := sNone; 
      AddToResult; 
      Inc(I); 
      Continue; 
     end; 
    end; 
    token := token + S[I]; 
    Inc(I); 
    end; 
    if token <> '' then 
    AddToResult; 
    if S[Length(S)] = ADelimiter then 
    AddToResult 
end;