¿Cómo dividir una cadena en T-SQL?

Question

Tengo un varchar @ a = 'a | b | c | d | e | f | g | h | i | j | k | l | m | n | o | p', que tiene | valores delimitados Quiero dividir esta variable en una matriz o una tabla. ¿Alguien tiene alguna idea al respecto?

Answer 1

Utilice una función con valores de tabla como esta,

CREATE FUNCTION Splitfn(@String varchar(8000), @Delimiter char(1))  
returns @temptable TABLE (items varchar(8000))  
as  
begin  
    declare @idx int  
    declare @slice varchar(8000)  

    select @idx = 1  
     if len(@String)<1 or @String is null return  

    while @idx!= 0  
    begin  
     set @idx = charindex(@Delimiter,@String)  
     if @idx!=0  
      set @slice = left(@String,@idx - 1)  
     else  
      set @slice = @String  

     if(len(@slice)>0) 
      insert into @temptable(Items) values(@slice)  

     set @String = right(@String,len(@String) - @idx)  
     if len(@String) = 0 break  
    end 
return  

end 

y conseguir que su variable y utilizar esta función como esta,

SELECT i.items FROM dbo.Splitfn(@a,'|') AS i 

Answer 2

En general, esta es una pregunta tan común aquí

Voy a dar la respuesta común: Arrays and Lists in SQL Server 2005 and Beyond por Erland Sommarskog

Yo recomendaría un table of numbers, no un bucle, para uso general.

Answer 3

prueba este:

declare @a varchar(10) 
set @a = 'a|b|c|' 
while len(@a) > 1 
begin 
insert into #temp 
select substring(@a,1,patindex('%|%',@a)-1); 
set @a = substring(@a,patindex('%|%',@a)+1,len(@a)) 
end; 

Answer 4

Aquí es una solución basada en XML alternativa. Parece tener un rendimiento similar al de la solución Splitfn().

Esto convierte varchar a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p en XML <a>a</a><a>b</a><a>c</a><a>d</a><a>e</a><a>f</a><a>g</a><a>h</a><a>i</a><a>j</a><a>k</a><a>l</a><a>m</a><a>n</a><a>o</a><a>p</a> y extrae el valor de cada nodo XML <a>.

declare @a  varchar(max); 
set @a = 'a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p'; 

declare @xml xml; 
set @xml  
    = '<a>'+replace(replace(replace(@a,'&','&amp;'),'<','&lt;'),'|','</a><a>')+'</a>'; 

SELECT x.n.value('.','VARCHAR(1)') AS singleValue 
FROM @xml.nodes('/a') AS x(n) 
;