Guardar imagen en una variedad de formatos de archivo

Question

Tengo una rutina procedure DrawStuff(ACanvas: TCanvas; const ARect: TRect) que dibuja algo en un rectángulo específico en un TCanvas. En este momento, llamo al DrawStuff con un lienzo de PaintBox. Ahora estoy agregando una opción Save as, en la que el usuario podrá seleccionar entre una variedad de formatos de archivo (bmp, wmf, jpg, ... - preferiblemente tantos descendientes de TGraphic como sea posible) para guardar los resultados de DrawStuff en .

Al llamar a TMetafile y guardar eso como "bla.bmp" o Assign al TPicture no funciona correctamente, p. Ej. produce archivos con extensión ".bmp" que no son bitmaps. Ahora mismo no puedo imaginar una solución que no implique especial carcasa todos los formatos de archivo único:

• bmp - Uso TBitmap.Canvas.
• wmf/fem: Use TMetafileCanvas.
• , etc, etc

¿Sabes tiene alguna idea para mí?

Answer 1

supongo una conversión "tonto" probablemente tan simple como esto:

type 
    TGraphicTypeEnum = (gteBMP, gteJPG, gteTIF, gtePNG); 

procedure SaveGraphicAs(AGraphic : TGraphic; AGraphicType : TGraphicTypeEnum; AFileName : String); 
var vGraphicClass : TGraphicClass; 
    vTargetGraphic : TGraphic; 
    vBmp : TBitmap; 
begin 

    case AGraphicType of 
    gteBMP : vGraphicClass := TBitmap; 
    gtejpg : vGraphicClass := TJPEGImage; 
    gtetif : vGraphicClass := TWICImage; 
    gtepng : vGraphicClass := TPngImage; 
    else 
    // EXIT; or raise... 
    end; 
    if aGraphic is vGraphicClass then //As suggested by Rob Kennedy 
    AGraphic.SaveToFile(AFileName) 
    else 
    begin 
    vBmp := nil; 
    vTargetGraphic := vGraphicClass.Create; 
    try 
     vBmp := TBitmap.Create; 
     vBmp.Assign(AGraphic); 
     vTargetGraphic.Assign(vBmp); 
     vTargetGraphic.SaveToFile(aFileName); 
    finally 
     vTargetGraphic.Free; 
     vBmp.Free; 
    end; 
    end; 
end; 

Asignación a un TPicture no funcionó, ya que cuando se asigna a un TPicture, TPicture convertirá el gráfico para la clase estás asignando desde.

Tenga en cuenta que en mi ejemplo, hay 2 capas de conversión, ya que la imagen original se convierte en mapa de bits antes de convertirse al formato final. Puede haber bastante pérdida de información en el proceso. La mayoría (¿todos?) Del tipo de gráfico saben cómo convertir a TBitmap y desde este, pero TJPEGImage no tiene idea de cómo convertir a TPngImage y viceversa.

Se puede desarrollar un método de conversión más eficiente que mantenga la transparencia y otros efectos específicos de un formato de archivo, pero eso es lo que yo sé. Pero dependiendo de tus necesidades, eso podría ser suficiente.