salida de redirección de DOS si hay salida

Question

Tengo una serie de líneas en un archivo por lotes (.bat) que se ejecuta en una máquina Windows, por ejemplo:

start /b prog.exe cmdparam1 cmdparam2 > test1.txt 
start /b prog.exe cmdparam1 cmdparam2 > test2.txt 

veces proj.exe devuelve nada (vacío) en lugar de datos útiles. En esos casos, no quiero generar un archivo de texto, ¿es esto algo fácilmente realizable en el lado del archivo por lotes? El comportamiento actual es que siempre se crea un archivo de texto, en el caso de salida vacía, es solo un archivo en blanco.

Answer 1

La solución jpe requiere que su lote principal sepa cuándo se han completado los procesos iniciados antes de que pueda verificar los tamaños del archivo de salida. Puede usar la opción START/WAIT, pero luego pierde la ventaja de correr en paralelo.

Puede utilizar el hecho de que la redirección a un archivo fallará si otro proceso ya ha redirigido la salida a ese mismo archivo. Cuando su lote principal puede redirigir a ellos con éxito, entonces sabrá que todos los procesos iniciados se han completado.

Probablemente debería redirigir stderr al archivo de salida, así como la salida estándar

@echo off 

::start the processes and redirect the output to the ouptut files 
start /b "" cmd /c prog.exe cmdparam1 cmdparam2 >test1.txt 2>&1 
start /b "" cmd /c prog.exe cmdparam1 cmdparam2 >test2.txt 2>&1 

::define the output files (must match the redirections above) 
set files="test1.txt" "test2.txt" 

:waitUntilFinished 
:: Verify that this parent script can redirect an unused file handle to the 
:: output file (append mode). Loop back if the test fails for any output file. 
:: Use ping to introduce a delay so that the CPU is not inundated. 
>nul 2>nul ping -n 2 ::1 
for %%F in (%files%) do (
    9>>%%F (
    rem 
) 
) 2>nul || goto :waitUntilFinished 

::Delete 0 length output files 
for %%F in (%files%) do if %%~zF==0 del %%F 

Answer 2

Solo delete all files with zero length. Editar: para acomodar el hecho de que start sin la bandera/ESPERA retornos antes de esperar el prog.exe para terminar, se podría crear el siguiente guión envoltorio progwrapper.bat para su prog.exe:

prog.exe "%1" "%2" > "%3" 
if %~z3==0 del "%3" 

luego llamar a la envoltura de su script principal:

start /b progwrapper.bat cmdparam1 cmdparam2 > test1.txt 
start /b progwrapper.bat cmdparam1 cmdparam2 > test2.txt 

etc.

Si PROG.EXE es una aplicación de interfaz gráfica de usuario, entonces debería haber un start /B /WAIT prog.exe en el progwrapper.bat.