¿Cómo seleccionar todos los nodos raíz o todos los secundarios en VirtualStringTree?

Question

Me gustaría seleccionar todos los nodos raíz o todos los nodos secundarios (no todos los nodos en un VirtualTreeView).
He tratado de utilizar este código para seleccionar todos los nodos raíz:

procedure SelectAllRoots; 
var 
    Node: PVirtualNode; 
begin 
    Form1.VirtualStringTree1.BeginUpdate; 
    Node := Form1.VirtualStringTree1.GetFirst; 
    while True do 
    begin 
    if Node = nil then 
     Break; 
    if not (vsSelected in Node.States) then 
     Node.States := Node.States + [vsSelected]; 
    Node := Form1.VirtualStringTree1.GetNext(Node); 
    end; 
    Form1.VirtualStringTree1.EndUpdate; 
end; 

me puede decir que hay un pequeño problema técnico. La selección está incompleta o se atasca. Qué estoy haciendo mal ?

Editar:
Uso MultiSelection.

Answer 1

1. Seleccionar todos los nodos raíz:

para seleccionar todos los nodos raíz, puede utilizar el siguiente procedimiento:

procedure SelectRootNodes(AVirtualTree: TBaseVirtualTree); 
var 
    Node: PVirtualNode; 
begin 
    AVirtualTree.BeginUpdate; 
    try 
    Node := AVirtualTree.GetFirst; 
    while Assigned(Node) do 
    begin 
     AVirtualTree.Selected[Node] := True; 
     Node := AVirtualTree.GetNextSibling(Node); 
    end; 
    finally 
    AVirtualTree.EndUpdate; 
    end; 
end; 

2. Seleccione todos los nodos hijos:

Para seleccionar todos los nodos secundarios, nivel independiente, debe usar recu función de respuesta como esta:

procedure SelectChildNodes(AVirtualTree: TBaseVirtualTree); 
var 
    Node: PVirtualNode; 

    procedure SelectSubNodes(ANode: PVirtualNode); 
    var 
    SubNode: PVirtualNode; 
    begin 
    SubNode := AVirtualTree.GetFirstChild(ANode); 
    while Assigned(SubNode) do 
    begin 
     SelectSubNodes(SubNode); 
     AVirtualTree.Selected[SubNode] := True; 
     SubNode := AVirtualTree.GetNextSibling(SubNode); 
    end; 
    end; 

begin 
    AVirtualTree.BeginUpdate; 
    try 
    Node := AVirtualTree.GetFirst; 
    while Assigned(Node) do 
    begin 
     SelectSubNodes(Node); 
     Node := AVirtualTree.GetNextSibling(Node); 
    end; 
    finally 
    AVirtualTree.EndUpdate; 
    end; 
end;