Seleccionar una última palabra de una cadena en xslt

Question

Solo quiero tomar el último elemento de una cadena que sea como esta "aaa-bbb-ccc-ddd" en xslt.

La salida debe ser "ddd" independientemente de '-'s.

Answer 1

XSLT/XPath 2.0 - con ayuda de la función tokenize() a dividir la cadena en el "-" y luego usar un filtro de predicados para seleccionar el último elemento de la secuencia:

<?xml version="1.0"?> 
<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="/"> 
     <xsl:value-of select="tokenize('aaa-bbb-ccc-ddd','-')[last()]"/> 
    </xsl:template> 
</xsl:stylesheet> 

XSLT/XPath 1.0 - usando a recursive template a buscar la última aparición de "-" y seleccionando la siguiente subcadena que:

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="/"> 
     <xsl:call-template name="substring-after-last"> 
      <xsl:with-param name="input" select="'aaa-bbb-ccc-ddd'" /> 
      <xsl:with-param name="marker" select="'-'" /> 
     </xsl:call-template> 
    </xsl:template> 

    <xsl:template name="substring-after-last"> 
     <xsl:param name="input" /> 
     <xsl:param name="marker" /> 
     <xsl:choose> 
      <xsl:when test="contains($input,$marker)"> 
       <xsl:call-template name="substring-after-last"> 
        <xsl:with-param name="input" 
      select="substring-after($input,$marker)" /> 
        <xsl:with-param name="marker" select="$marker" /> 
       </xsl:call-template> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:value-of select="$input" /> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet>