defecto ordenar

Question

lectura a través this, me vino a la broca en los valores por defecto para los argumentos de la función:

fill = (container, liquid = "coffee") -> 
    "Filling the #{container} with #{liquid}..." 

Eso es ordenada, pero luego intentó esto:

fill = (container="mug", liquid = "coffee") -> 
    "Filling the #{container} with #{liquid}..." 

alert fill(liquid="juice") 

y se lo inesperado alerta con "Filling the juice with coffee...". Entonces intenté esto:

fill = (container="mug", liquid = "coffee") -> 
    "Filling the #{container} with #{liquid}..." 

alert fill(null, "juice") 

y funcionó. Aunque no es lindo. ¿Hay una mejor manera, o es esta la manera idiomática de hacer esto?

Answer 1

fill = ({container, liquid} = {}) -> 
    container ?= "mug" 
    liquid ?= "coffee" 

    "Filling the #{container} with #{liquid}..." 

alert fill(liquid: "juice", container: "glass") 
alert fill() 

fill = (quantity="500 mL", {container, liquid} = {}) -> 
    container ?= "mug" 
    liquid ?= "coffee" 

    "Filling the #{container} with #{quantity} of #{liquid}..." 

alert fill("1L", liquid: "juice", container: "glass") 
alert fill() 
alert fill "1L" 
alert fill "1L", liquid: "water" 

Answer 2

Actualmente, no hay forma de llamar con argumentos con nombre. Se requeriría conocer los argumentos (nombres, posiciones y/o valores por defecto) en el sitio de la llamada, lo que no siempre es factible en javascript/coffeescript.

En cambio si tiene muchos argumentos y que desea nombrarlos y tienen valores por defecto, se podría hacer algo como esto:

fill = (opts = {}) -> 
    opts.container ?= "mug" 
    opts.liquid ?= "coffee" 
    "Filling the #{opts.container} with #{opts.liquid}..." 

alert fill 
    liquid:"juice" 
    container:"cup" 

alert fill 
    liquid:"juice" 

alert fill() 

Answer 3

Amir y Jeremy ya tienen esto. Como señalan, container="mug" en la lista de argumentos de una función es realmente solo una abreviatura de container ?= "mug" en el cuerpo de la función.

Permítanme añadir que al llamar a funciones,

fill(liquid="juice") 

significa lo mismo que en JavaScript: En primer lugar, asignar el valor a la variable "juice"liquid; luego pase liquid junto al fill. CoffeeScript no hace nada especial aquí, y liquid tiene el mismo alcance en esa situación que lo haría fuera de la llamada a la función.

Por cierto, he sugerido que la sintaxis argumento por defecto debería ser más potente permitiendo que los argumentos que hay que saltar (por ejemplo (first, middle ?= null, last) -> sería asignar valores a first y last si sólo se pasan dos argumentos), y que el ?= la sintaxis debe usarse en lugar de =. Es posible que desee expresar su apoyo a esa propuesta aquí: issue 1091.