¿Hay alguna forma de mostrar el tiempo de compilación de una solución completa en Visual Studio?

Question

Sé que hay a way to display the build time of each project contained in a solution in visual studio. Pero lo que estoy buscando es el tiempo total que tomó construir una solución completa, desde el momento en que hice clic en la compilación, hasta el momento en que se hizo.

¿Hay alguna forma de hacerlo? Ejecución de Visual Studio 2008.

Answer 1

EDIT: Aquí está una manera que usted puede escribir el tiempo de construcción directamente a la ventana de generación.

Abra Visual Studio Macro IDE.
Navegue a MyMacros> EnvironmentEvents.
En MyMacros, agregue una referencia a System.Windows.Forms (para que el código siguiente muestre una ventana emergente).
añadir este código al módulo EnvironmentEvents:

Dim buildStart As Date 

Private Function IsBuild(ByVal scope As EnvDTE.vsBuildScope, ByVal action As EnvDTE.vsBuildAction) As Boolean 
    Return scope = vsBuildScope.vsBuildScopeSolution AndAlso (action = vsBuildAction.vsBuildActionBuild OrElse action = vsBuildAction.vsBuildActionRebuildAll) 
End Function 

Private Sub BuildEvents_OnBuildBegin(ByVal Scope As EnvDTE.vsBuildScope, ByVal Action As EnvDTE.vsBuildAction) Handles BuildEvents.OnBuildBegin 
    If (IsBuild(Scope, Action)) Then 
     buildStart = Date.Now 
    End If 
End Sub 

Private Sub BuildEvents_OnBuildDone(ByVal Scope As EnvDTE.vsBuildScope, ByVal Action As EnvDTE.vsBuildAction) Handles BuildEvents.OnBuildDone 
    If (IsBuild(Scope, Action)) Then 
     Dim buildTime = Date.Now - buildStart 
     WriteToBuildWindow(String.Format("Build time: {0}", buildTime.ToString)) 
    End If 
End Sub 

Private Sub WriteToBuildWindow(ByVal message As String) 
    Dim win As Window = DTE.Windows.Item(EnvDTE.Constants.vsWindowKindOutput) 
    Dim ow As OutputWindow = CType(win.Object, OutputWindow) 
    For Each owPane As OutputWindowPane In ow.OutputWindowPanes 
     If (owPane.Name.Equals("Build")) Then 
      owPane.OutputString(message) 
      Exit For 
     End If 
    Next 
End Sub 

Cuando a construir o reconstruir la solución completa, al final, la construcción/reconstrucción duración será impreso a la ventana de resultados de generación. Puede cambiar las condiciones en IsBuild para adaptarlas a sus preferencias.

Answer 2

Herramientas-> Opciones-> Proyectos y Soluciones> VC++ Proyecto Configuración-> Construir sincronización