Archivos por lotes: enumere todos los archivos en un directorio con rutas relativas

Question

Acerca de los archivos por lotes de Windows: ¿Hay alguna manera de enumerar todos los archivos (o todos los tipos específicos) en un directorio determinado y sus subdirectorios, incluidas las rutas relativas a el directorio actual (o el de búsqueda) en la lista?

Por ejemplo, si quiero todos los archivos txt en el directorio actual y sus subdirectorios con sus rutas completas, que puedo hacer

for /r . %%g in (*.txt) do echo %%g >> C:\temp\test.txt 

o

dir *.txt /b /s >> C:\temp\test.txt 

y voy a conseguir algo como

C:\test\Doc1.txt 
C:\test\subdir\Doc2.txt 
C:\test\subdir\Doc3.txt 

Si hago

for /r . %%g in (*.txt) do echo %%~nxg >> C:\temp\test.txt 

voy a conseguir algo como

Doc1.txt 
Doc2.txt 
Doc3.txt 

Pero lo que realmente quiero es:

Doc1.txt 
subdir\Doc2.txt 
subdir\Doc3.txt 

¿Es posible?

Si mi publicación es demasiado confusa: básicamente quiero "List files recursively in Linux CLI with path relative to the current directory", solo para Windows.

Answer 1

Se puede conseguir simplemente la longitud de caracteres del directorio actual, y eliminarlos de su lista absoluta

setlocal EnableDelayedExpansion 
for /L %%n in (1 1 500) do if "!__cd__:~%%n,1!" neq "" set /a "len=%%n+1" 
setlocal DisableDelayedExpansion 
for /r . %%g in (*.log) do (
    set "absPath=%%g" 
    setlocal EnableDelayedExpansion 
    set "relPath=!absPath:~%len%!" 
    echo(!relPath! 
    endlocal 
) 

Answer 2

Esta respuesta no funcionará correctamente con las rutas de raíz que contiene el signo igual (=). (Gracias @dbenham por señalarlo.)

---

EDITADO: ha solucionado el problema con rutas que contienen !, nuevamente descubierto por @dbenham (gracias!).

Como alternativa al cálculo de la longitud y extraer subcadenas se puede utilizar un enfoque diferente:

• tienda de la ruta raíz;

• borre la ruta raíz de las rutas de archivos.

Aquí está mi intento (que trabajó para mí):

@ECHO OFF 
SETLOCAL DisableDelayedExpansion 
SET "r=%__CD__%" 
FOR /R . %%F IN (*) DO (
    SET "p=%%F" 
    SETLOCAL EnableDelayedExpansion 
    ECHO(!p:%r%=! 
    ENDLOCAL 
) 

La variable r se le asigna el directorio actual. A menos que el directorio actual sea el directorio raíz de una unidad de disco, no terminará con \, que modificaremos al agregar el carácter.(Ya no es el caso, ya que el script ahora lee la variable __CD__, cuyo valor siempre termina en \ (gracias @jeb!), en lugar de CD.)

En el ciclo, almacenamos la ruta del archivo actual en una variable. Luego damos salida a la variable, eliminando el camino raíz a lo largo del camino.

Answer 3

Por supuesto, es posible escribir un algoritmo recursivo en el lote que le da un control exacto de lo que haces en cada subdirectorio anidado:

@echo off 
set mypath= 
call :treeProcess 
goto :eof 

:treeProcess 
setlocal 
for %%f in (*.txt) do echo %mypath%%%f 
for /D %%d in (*) do (
    set mypath=%mypath%%%d\ 
    cd %%d 
    call :treeProcess 
    cd .. 
) 
endlocal 
exit /b 

Answer 4

El (pero no la más rápida) forma más sencilla de recorrer un árbol de directorios y enumerar rutas de archivos relativas es usar FORFILES.

forfiles /s /m *.txt /c "cmd /c echo @relpath" 

Las rutas relativas se cotizará con un líder .\ como en

".\Doc1.txt" 
".\subdir\Doc2.txt" 
".\subdir\Doc3.txt" 

cotizaciones para quitar:

for /f %%A in ('forfiles /s /m *.txt /c "cmd /c echo @relpath"') do echo %%~A 

Para eliminar las citas y el principal .\:

setlocal disableDelayedExpansion 
for /f "delims=" %%A in ('forfiles /s /m *.txt /c "cmd /c echo @relpath"') do (
    set "file=%%~A" 
    setlocal enableDelayedExpansion 
    echo !file:~2! 
    endlocal 
) 

o sin el uso de expansión retardada

for /f "tokens=1* delims=\" %%A in (
    'forfiles /s /m *.txt /c "cmd /c echo @relpath"' 
) do for %%F in (^"%%B) do echo %%~F 

Answer 5

@echo on>out.txt 
@echo off 
setlocal enabledelayedexpansion 
set "parentfolder=%CD%" 
for /r . %%g in (*.*) do (
    set "var=%%g" 
    set var=!var:%parentfolder%=! 
    echo !var! >> out.txt 
)