excel vba: Tipos especiales - Funciones como argumentos de funciones

Question

No hay un tipo especial para funciones en VBA. Es difícil para mí ver cómo agregar funciones como argumentos a funciones en Excel VBA.

Lo que estoy tratando de lograr es algo como esto:

function f(g as function, x as string) as string 
     f = g(x) 
end function 

Actualmente, tengo un grupo de pequeños todas las funciones que se repiten, pero con una llamada a una función específica.

Answer 1

Desde su código, la función g toma un parámetro de cadena y devuelve una cadena. Sugiero crear un módulo de clase llamado IStringFunction para actuar como la definición de una interfaz que todas las funciones apoyarán, por lo tanto:

módulo de clase: IStringFunction

Public Function Evaluate(ByVal s As String) As String 
End Function 

A continuación, crea un par de ejemplos de funciones la implementación de esta interfaz:

módulo de clase: HelloStringFunction

Implements IStringFunction 

Public Function IStringFunction_Evaluate(ByVal s As String) As String 
    IStringFunction_Evaluate = "hello " & s 
End Function 

módulo de clase: GoodbyeStringFunction

Implements IStringFunction 

Public Function IStringFunction_Evaluate(ByVal s As String) As String 
    IStringFunction_Evaluate = "goodbye " & s 
End Function 

... y, finalmente, un código de prueba para ejercer las funciones:

(Estándar) Módulo: Prueba

Sub Test() 

    Dim oHello As New HelloStringFunction 
    Dim oGoodbye As New GoodbyeStringFunction 

    MsgBox Evaluate(oHello, "gary") 
    MsgBox Evaluate(oGoodbye, "gary") 

End Sub 

Private Function Evaluate(ByVal f As IStringFunction, ByVal arg As String) As String 
    Evaluate = f.Evaluate(arg) 
End Function 

Nota que la clase que implementa la interfaz debe tener métodos llamados <Interface>_<Method> como en el ejemplo anterior, no solo <Method> como era de esperar.

Descargar el simple demo o intermediate demo aquí

Answer 2

Desde VBA tiene sus raíces en un lenguaje interactivo, que siempre ha tenido la capacidad de ejecutar texto:

function f(g as string, x as string) as string 
     f = application.run(g,x) 
end function 

MyStringA = f("functionA",string1) 
MyStringB = f("functionB",string1) 

Answer 3

Es posible pasar una función como un argumento, y obtiene exactamente el comportamiento que busca, pero es un poco hacky. Esto se logra mediante la explotación de la propiedad predeterminada de una clase,

crear una clase que contiene la función myFunction

Public Function sayHi(ByVal s As String) As String 
    sayHi = "Hi " & s 
End Function 

exportarlo, y abra la.archivo cls en un editor de texto

Debe ver en alguna parte del archivo, una línea que define su función

Public Function sayHi(ByVal s As String) As String 

Debajo de ella, añada la línea Attribute Value.VB_UserMemId = 0, por lo que ahora se ve así:

Public Function sayHi(ByVal s As String) As String 
Attribute Value.VB_UserMemId = 0 
    sayHi = "Hi " & s 
End Function 

Lo que ha hecho aquí es marcar sayHi como default property de la clase. Ahora se puede llamar a la función de la clase de objeto solos class(args), en lugar de class.function(args)

Guardar el archivo modificado y la importación en su proyecto de VBA

módulo de prueba

Sub test() 
    Dim parameterFunction As Object   'this is what we'll be passing to our routine 
    Set parameterFunction = New myFunction 'create instance of the function object 
    MsgBox f(parameterFunction, "Greedo") 
End Sub 

Function f(ByVal g As Object, ByVal x As String) As String 
     f = g(x) 
End Function 

* NB, este forma en que puede pasar cualquier función; pero en su lugar puede especificar ByVal g As IStringFunction para obtener solo el subconjunto con la interfaz correcta según Gary McGill's answer