¿Cómo decirle a Mathematica que reemplace 0 por potencia 0 por 1?

Question

Expertos;

Dado

f = (#1^#2) & 

¿Hay una manera de definir 'f' por encima de tal manera que si # 1 y # 2 son ambos cero, entonces el valor de la función pura 'f' debe ser de 1?

de manera que cuando escribo

f[0,0] 

devolverá 1 y no indeterminado?

por cierto, sé que puedo escribir

f = (If[#1 == 0 && #2 == 0, 1, #1^#2]) & 

pero quería una regla general o patrón, así que no tiene que escribir estos controles, ya que la función pura puede ser más complicado (muchos # en ella) y no quiero hacer muchas de estas comprobaciones 'si entonces no' para cada posible 0^0 que pueda aparecer.

gracias

Actualización:

Puede ser Debo aclarar más por qué estoy haciendo esto.
Tengo un usuario que selecciona una función de un menú. La función es

a x^n0 + b y^n1 + c x^n2 y^n3 

Cuando en lo anterior, los parámetros 'n0', 'n1', 'n2' y 'n3' también se pueden seleccionar a partir de controles deslizantes, y estos pueden ser cero.

Ahora, 'x' y 'y' son coordenadas, y estas también pueden ser cero.

Por lo tanto, es posible que 0^0 pueda encontrarse al evaluar la función anterior.

Hay muchos casos para verificar, al hacerlo yo mismo. Por ejemplo 'y^n3' puede ser 0^0 y no el otro, y^n1 puede ser 0^0 y no el otro, x^n2 y^n3 pueden ser tanto 0^0 como no los demás, etc. , y entonces tengo que definir muchos casos diferentes. (16 posibles casos, creo).

Y estoy tratando de evitar esto. Si puedo decirle a Mathematica que reemplace 0^0 por 1 en un nivel inferior, entonces la vida será más simple.

Actualización 12/7/11 Gracias por las respuestas y los comentarios de todos, todos son muy útiles y resuelven mi problema y he aprendido de ellos.

He seleccionado la respuesta de Leonid, ya que me permitió resolver mi problema con la menor cantidad de codificación adicional.

He aquí un pequeño ejemplo

Manipulate[Row[{format[x, n], "=", eval[x, n]}], 
{{x, 0.0, "x="}, 0, 1, .1, Appearance -> "Labeled"}, 
{{n, 0.0, "n="}, 0, 1, .1, Appearance -> "Labeled"}, 
Initialization :> 
    (
    format[x_, n_] := HoldForm["(" x ")"^n]; 
    eval = Unevaluated[#1^#2] /. HoldPattern[0.0^0.0] :> 0.0 & 
    ) 
] 

utilizo números reales en todas partes de mi código (que es un solucionador de PDE numérica), así que por eso utilicé 0.0 en lo anterior y no 0^0 para encajar con lo que estoy haciendo

Answer 1

Estoy de acuerdo con la respuesta de @Deep amarillo, pero si usted insiste en una función pura, aquí es una manera:

f = Unevaluated[#1^#2] /. HoldPattern[0^0] :> 1 & 

EDITAR

El permanecer dentro del ámbito de las funciones puras, la situación que describió en su edición puede abordarse de la misma manera que mi solución a su ejemplo original específico. Puede automatizar esto con un poco de metaprogramming, que define la siguiente función del transformador:

z2zProtect[Function[body_]] := 
    Function[Unevaluated[body] /. HoldPattern[0^0] :> 1] 

Entonces, mi código anterior se puede reescribir como:

f = z2zProtect[#1^#2 &] 

Pero usted puede es esto de manera más general, por ejemplo:

ff = z2zProtect[#1^#2 + 2 #2^#3 + 3 #3^#4 &] 

In[26]:= ff[0,0,0,0] 
Out[26]= 6 

Answer 2

Puede intentar escribirlo como f = Quiet[Check[#1^#2,1]] &.

Quiet suprimirá el mensaje "Power::indet: "Indeterminate expression 0^0 encountered." y Check reemplazará el resultado con 1 si es indeterminado.

Probablemente sea mejor usar alguna función como s = Quiet[Check[#1, 1]] y envolver sus expresiones en ella.

Answer 3

Por supuesto, hay muchas maneras de hacer las cosas en Mathematica, pero un modismo de diseño que a menudo uso es escribir la "función" (en realidad, un patrón) con una especificidad decreciente. Mathematica tiene la propiedad de que aplicará patrones más específicos antes de que sea menos específico.

Por lo tanto, para su caso que acababa de escribir:

Clear[f]; 
f[0, 0] = 1; 
f[a_, b_] := a^b; 

Asumo que espera trabajar con valores enteros ya que es el contexto habitual para este tipo de situaciones, por ejemplo, al evaluar las funciones básicas de Bernstein.

Answer 4

Estoy un poco sorprendido de que la solución trivial (aunque ligeramente peligrosa) no haya sido mencionada anteriormente. Si realmente no espera que aparezca la expresión 0^0 en un contexto en el que (a) le preocuparía que ocurriera, o (b) quisiera evaluarlo en algo distinto de 1, simplemente puede intentar

Unprotect[Power]; 
Power[0, 0] = 1; 
Protect[Power]; 
0^0 

que necesitaba esta revisión en una situación en la que una función complicada tenía un número de llamadas a las expresiones de la forma x^n donde x es real y n es un número entero, en cuyo caso 0^0 debe ser visto como el límite de x^0=1 como x va a 0.

Es importante tener en cuenta, sin embargo, que hacer esto 'contaminará' Power para la sesión actual del kernel, y puede por lo tanto romper otros cuadernos que se ejecutan simultáneamente y para los cuales las condiciones (a) y (b) pueden no ser válidas.Dado que Power se encuentra en el contexto System՝ en lugar de Global՝, puede ser difícil separar los contextos de diferentes blocs de notas para evitar conflictos producidos por esta corrección.