¿Cómo restar una matriz de una matriz?

Question

cuando intento el siguiente

#!/usr/bin/perl 

use strict; 
use warnings; 
use Data::Dumper; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 

print Dumper [grep {not @bl} @a]; 

puedo obtener una matriz vacía. Hubiera esperado que @bl se restara de @a, por lo que la salida fue yellow purple pink.

¿Qué pasa aquí?

Answer 1

lo necesario para convertir @bl en un hash para realizar la diferencia de conjuntos:

my %in_bl = map {$_ => 1} @bl; 
my @diff = grep {not $in_bl{$_}} @a; 

Answer 2

Ver perlfaq4: How do I compute the difference of two arrays?

En su código, not es, probablemente, no hacer lo que piensa que está haciendo.

not @bl siempre habrá 1 si @bl es una matriz vacía, y si undef@bl no está vacío. No significa "elementos que no están en @bl" en ningún sentido.

Answer 3

@b1 se evalúa como verdadera (que es una matriz con un no-cero número de elementos), por lo que la prueba booleana en su grep constructo (not @b1) siempre devolverá falso. grep filtra una matriz que devuelve solo los elementos para los cuales la prueba booleana devuelve verdadero.

Debe probar para ver si $_ (el elemento de la matriz actualmente bajo consideración) está en @bl o no. Una forma de hacer esto es generar un hash temporal utilizando @bl como las claves, a continuación, en su cheque comunicado grep la presencia de $_ en las claves hash:

#!/usr/bin/perl 

use strict; 
use warnings; 
use Data::Dumper; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 

# create a hash 
my %h; 

# nifty trick - use a hash slice to populate the 
# hash. The values are irrelevant so we'll use @bl 
# for those too 
@h{@bl} = @bl; 

print Dumper [grep {!exists $h{$_}} @a]; 

Answer 4

Otra forma, usando la función minus del Acme::Tools módulo CPAN:

use strict; 
use warnings; 
use Data::Dumper; 
use Acme::Tools qw(minus); 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 
my @diff = minus(\@a, \@bl); 
print Dumper(\@diff); 

__END__ 

$VAR1 = [ 
      'yellow', 
      'purple', 
      'pink' 
     ]; 

Answer 5

Otra opción usando perl5i:

use perl5i::2; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 
my @diff = @a->diff(\@bl); 

say @diff->mo->perl; 

Answer 6

Desde Perl 5.18.0 el operador de Smartmatch se considera experimental: The smartmatch family of features are now experimental. Por eso, ya no usaría esta solución más abajo.

Otra manera con el SmartMatch-operador (si tiene perl- versión 5.010 o superior):

#!/usr/bin/env perl 
use warnings; 
use 5.012; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 

my @s = grep{ not $_ ~~ @bl } @a; 
say "@s"; # yellow purple pink 

Answer 7

Otra forma es utilizar:

List::Compare CPAN module 
use List::Compare ; 
... 
my $compare_obj 
    = List::Compare->new(\@a , \@b1) ; 
@diff = $compare_obj->get_Lonly() ; 
...