Buscar y reemplazar cadenas en mi texto con VBScript

Question

Estoy buscando un archivo VBScript que realice una búsqueda y lo reemplace en archivos (por ejemplo, 1.txt 2.xml). Tengo el archivo "1.txt" que contiene la palabra "temporal" y quiero cambiarlo a "permanente". Como obtengo este archivo mucho, necesito un script para ello.

Cada vez que intento escribir un script que contiene abrir un archivo txt y reemplazar el comando, no lo hace.

Encontré una secuencia de comandos que cambia este archivo con otro archivo y hace el cambio dentro, pero esto no es lo que estoy buscando.

Answer 1

probar este

If WScript.Arguments.Count <> 3 then 
    WScript.Echo "usage: Find_And_replace.vbs filename word_to_find replace_with " 
    WScript.Quit 
end If 

FindAndReplace WScript.Arguments.Item(0), WScript.Arguments.Item(1), WScript.Arguments.Item(2) 
WScript.Echo "Operation Complete" 

function FindAndReplace(strFilename, strFind, strReplace) 
    Set inputFile = CreateObject("Scripting.FileSystemObject").OpenTextFile(strFilename, 1) 
    strInputFile = inputFile.ReadAll 
    inputFile.Close 
    Set inputFile = Nothing 
    Set outputFile = CreateObject("Scripting.FileSystemObject").OpenTextFile(strFilename,2,true) 
    outputFile.Write Replace(strInputFile, strFind, strReplace) 
    outputFile.Close 
    Set outputFile = Nothing 
end function 

Guardar esto en un archivo llamado Find_And_Replace.vbs, que luego se puede utilizar en la línea de comando como este.

[C:\]> Find_And_Replace.vbs "C:\1.txt" "temporary" "permanent" 

* Este método es sensible a mayúsculas "Este"! = "Este"

Si no desea leer el archivo en la memoria, se puede utilizar un archivo temporal como este.

If WScript.Arguments.Count <> 3 then 
    WScript.Echo "usage: Find_And_replace.vbs filename word_to_find replace_with " 
    WScript.Quit 
end If 

FindAndReplace WScript.Arguments.Item(0), WScript.Arguments.Item(1), WScript.Arguments.Item(2) 
WScript.Echo "Operation Complete" 

function FindAndReplace(strFile, strFind, strReplace) 
    Set objFSO = CreateObject("Scripting.FileSystemObject") 
    Set objInputFile = objFSO.OpenTextFile(strFile,1) 
    strTempDir = objFSO.GetSpecialFolder(2) 
    Set objTempFile = objFSO.OpenTextFile(strTempDir & "\temp.txt",2,true) 
    do until objInputFile.AtEndOfStream 
     objTempFile.WriteLine(Replace(objInputFile.ReadLine, strFind, strReplace)) 
    loop 
    objInputFile.Close 
    Set objInputFile = Nothing 
    objTempFile.Close 
    Set objTempFile = Nothing 
    objFSO.DeleteFile strFile, true 
    objFSO.MoveFile strTempDir & "\temp.txt", strFile 
    Set objFSO = Nothing 
end function 

Answer 2

Puede probar esta versión que no sorber todo el archivo en la memoria:

Set objFS = CreateObject("Scripting.FileSystemObject") 
strFile=WScript.Arguments.Item(0) 
strOld=WScript.Arguments.Item(1) 
strNew=WScript.Arguments.Item(2) 
Set objFile = objFS.OpenTextFile(strFile) 
Do Until objFile.AtEndOfStream 
strLine = objFile.ReadLine 
     if Instr(strLine,strOld)> 0 Then 
      strLine=Replace(strLine,strOld,strNew) 
     End If 
WScript.Echo strLine 
Loop 

Uso:

c:\test> cscript //nologo find_replace.vbs file oldtext newtext