Búsqueda a través de una nota en Delphi?

Question

¿Alguien puede darme algún código simple que me daría la posibilidad de buscar una cadena simple en un memorándum y lo han puesto de manifiesto en la nota después de ser encontrado?

Answer 1

function TForm1.FindText(const aPatternToFind: String):Boolean; 
    var 
    p: Integer; 
    begin 
    p := pos(aPatternToFind, Memo1.Text); 
    Result := (p > 0); 
    if Result then 
     begin 
     Memo1.SelStart := p; 
     Memo1.SelLength := Length(aPatternToFind); 
     Memo1.SetFocus; // necessary so highlight is visible 
     end; 
    end; 

Esto NO busca entre líneas si WordWrap es verdadero.

Answer 2

Esta búsqueda permite la envoltura documento, la caja (en) búsqueda sensible y búsqueda de la posición del cursor.

type 
    TSearchOption = (soIgnoreCase, soFromStart, soWrap); 
    TSearchOptions = set of TSearchOption; 


function SearchText(
    Control: TCustomEdit; 
    Search: string; 
    SearchOptions: TSearchOptions): Boolean; 
var 
    Text: string; 
    Index: Integer; 
begin 
    if soIgnoreCase in SearchOptions then 
    begin 
    Search := UpperCase(Search); 
    Text := UpperCase(Control.Text); 
    end 
    else 
    Text := Control.Text; 

    Index := 0; 
    if not (soFromStart in SearchOptions) then 
    Index := PosEx(Search, Text, 
     Control.SelStart + Control.SelLength + 1); 

    if (Index = 0) and 
     ((soFromStart in SearchOptions) or 
     (soWrap in SearchOptions)) then 
    Index := PosEx(Search, Text, 1); 

    Result := Index > 0; 
    if Result then 
    begin 
    Control.SelStart := Index - 1; 
    Control.SelLength := Length(Search); 
    end; 
end; 

Puede establecer HideSelection = False en la nota para mostrar la selección incluso si la nota no está enfocada.

uso como esto:

SearchText(Memo1, Edit1.Text, []); 

permite la búsqueda ediciones también.