Correo "No se puede continuar" para una función de AppleScript

Question

Estoy tratando de escribir un AppleScript para usarlo con Mail (en Snow Leopard) para guardar adjuntos de imágenes de mensajes a una carpeta. La parte principal de la AppleScript es:

property ImageExtensionList : {"jpg", "jpeg"} 
property PicturesFolder : path to pictures folder as text 
property SaveFolderName : "Fetched" 
property SaveFolder : PicturesFolder & SaveFolderName 

tell application "Mail" 
    set theMessages to the selection 
    repeat with theMessage in theMessages 
    repeat with theAttachment in every mail attachment of theMessage 
     set attachmentFileName to theAttachment's name 
     if isImageFileName(attachmentFileName) then 
     set attachmentPathName to SaveFolder & attachmentFileName 
     save theAttachment in getNonexistantFile(attachmentPathName) 
     end if   
    end repeat 
    end repeat 
end tell 

on isImageFileName(theFileName) 
    set dot to offset of "." in theFileName 
    if dot > 0 then 
    set theExtension to text (dot + 1) thru -1 of theFileName 
    return theExtension is in ImageExtensionList 
    end if 
    return false 
end isImageFileName 

Cuando se ejecuta, me sale el error:

error "Mail got an error: Can’t continue isImageFileName." number -1708

donde el error -1708 es:

Event wasnt handled by an Apple event handler.

Sin embargo, si copiar/pegar el isImageFileName() en otra secuencia de comandos como:

property ImageExtensionList : {"jpg", "jpeg"} 

on isImageFileName(theFileName) 
    set dot to offset of "." in theFileName 
    if dot > 0 then 
    set theExtension to text (dot + 1) thru -1 of theFileName 
    return theExtension is in ImageExtensionList 
    end if 
    return false 
end isImageFileName 

if isImageFileName("foo.jpg") then 
    return true 
else 
    return false 
end if 

funciona bien. ¿Por qué Mail se queja de esto?

Answer 1

Pruebe "my isImageFileName". No es correo, solo una peculiaridad de AppleScript.

Answer 2

Puede ser un capricho, pero tiene una explicación. Si se encuentra en un bloque tell application "whatever", todas las llamadas se realizan en el espacio de nombres del diccionario de esa aplicación, no en el del script. Por eso, tiene que decirle explícitamente a AppleScript que vuelva a mirar el script en busca del nombre. Decir my es como decir tell me, indicando al script dónde buscar la función.