¿Cómo obtener el nombre del grupo de resaltado debajo del cursor en vim?

Question

Normalmente personalizo el existente colorscheme para satisfacer mis necesidades.

Si pudiera obtener el nombre del grupo de sintaxis bajo el cursor, me sería de gran ayuda, al igual que Firebug pero en Vim. Me gustaría saber cómo hacerlo.

Answer 1

Hay esta función que estaba flotando alrededor de la web cuando estaba haciendo lo mismo:

function! SynStack() 
    if !exists("*synstack") 
    return 
    endif 
    echo map(synstack(line('.'), col('.')), 'synIDattr(v:val, "name")') 
endfunc 

Answer 2

Prueba esto:

" diagnostics {{{ 
if has('balloon_eval') 
    nnoremap <F12>   : setl beval!<CR> 
    set bexpr=InspectSynHL() 
endif 
fun! InspectSynHL() 
    let l:synNames = [] 
    let l:idx = 0 
    for id in synstack(v:beval_lnum, v:beval_col) 
     call add(l:synNames, printf('%s%s', repeat(' ', idx), synIDattr(id, 'name'))) 
     let l:idx+=1 
    endfor 
    return join(l:synNames, "\n") 
endfun 
"}}} 

Answer 3

La siguiente función es la salida tanto el nombre de la sintaxis grupo y el grupo de sintaxis traducida del carácter en el que se encuentra el cursor:

function! SynGroup()                
    let l:s = synID(line('.'), col('.'), 1)          
    echo synIDattr(l:s, 'name') . ' -> ' . synIDattr(synIDtrans(l:s), 'name') 
endfun 

Para hacer esto más conveniente, puede ser envuelto en un comando personalizado o enlace de clave.

¿Cómo funciona esto:

• line('.') y col('.') devuelve la posición actual
• synID(...) devuelve un ID de sintaxis numérico
• synIDtrans(l:s) traduce el identificador de sintaxis numérico l:s siguiendo relieve los vínculos
• synIDattr(l:s, 'name') devuelve el nombre correspondiente a la sintaxis numérica ID

Esto se hará eco de algo como:

vimMapModKey -> Special