Comandos de lote de Windows para leer la primera línea del archivo de texto

Question

¿Cómo puedo leer la primera línea de un archivo de texto usando un archivo por lotes de Windows? Como el archivo es grande, solo quiero tratar con la primera línea.

Answer 1

Aquí hay un archivo por lotes de propósito general para imprimir las líneas superiores n de un archivo como la utilidad GNU head, en lugar de solo una línea.

@echo off 

if [%1] == [] goto usage 
if [%2] == [] goto usage 

call :print_head %1 %2 
goto :eof 

REM 
REM print_head 
REM Prints the first non-blank %1 lines in the file %2. 
REM 
:print_head 
setlocal EnableDelayedExpansion 
set /a counter=0 

for /f ^"usebackq^ eol^=^ 

^ delims^=^" %%a in (%2) do (
     if "!counter!"=="%1" goto :eof 
     echo %%a 
     set /a counter+=1 
) 

goto :eof 

:usage 
echo Usage: head.bat COUNT FILENAME 

Por ejemplo:

Z:\>head 1 "test file.c" 
; this is line 1 

Z:\>head 3 "test file.c" 
; this is line 1 
    this is line 2 
line 3 right here 

actualmente no cuentan las líneas en blanco. También está sujeto a la restricción de longitud de línea de archivo por lotes de 8 KB.

Answer 2

Es posible probar esto:

@echo off 

for /f %%a in (sample.txt) do (
    echo %%a 
    exit /b 
) 

edición O, supongamos que tiene cuatro columnas de datos y desea de la 5ª fila hasta la parte inferior, intente esto:

@echo off 

for /f "skip=4 tokens=1-4" %%a in (junkl.txt) do (
    echo %%a %%b %%c %%d 
) 

Answer 3

Gracias a thetalkingwalnut con la respuesta Windows batch command(s) to read first line from text file se me ocurrió la siguiente solución:

@echo off 
for /f "delims=" %%a in ('type sample.txt') do (
echo %%a 
exit /b 
) 

Answer 4

Basándose en las respuestas de otras personas. Ahora que le permite especificar el archivo que desea leer y la variable que desea el resultado pone en:

@echo off 
for /f "delims=" %%x in (%2) do (
set %1=%%x 
exit /b 
) 

Esto significa que puede utilizar lo anterior como esto (suponiendo que llamaste getline.bat)

c:\> dir > test-file 
c:\> getline variable test-file 
c:\> set variable 
variable= Volume in drive C has no label. 

Answer 5

Un forro, útil para redirigir la salida estándar con ">":

@for /f %%i in ('type yourfile.txt') do @echo %%i & exit 

Answer 6

Nota, los enfoques de archivos por lotes se limitará a la línea de límite para el procesador de comandos DOS - ver What is the command line length limit?.

De modo que si intenta procesar un archivo que tiene alguna línea más que caracteres, la secuencia de comandos saltará simplemente porque no se puede retener el valor.

Answer 7

Uh ustedes ...

C:\>findstr /n . c:\boot.ini | findstr ^1: 

1:[boot loader] 

C:\>findstr /n . c:\boot.ini | findstr ^3: 

3:default=multi(0)disk(0)rdisk(0)partition(1)\WINNT 

C:\> 

Answer 8

eh? imo esto es mucho más simple

set /p texte=< file.txt 
    echo %texte% 

Answer 9

El problema con las soluciones EXIT/B, cuando más realista dentro de un archivo por lotes que sólo una parte de la misma es la siguiente. No hay procesamiento posterior dentro de dicho archivo por lotes después de EXIT/B. Por lo general, hay mucho más en lotes que solo una tarea limitada.

Para contrarrestar ese problema

@echo off & setlocal enableextensions enabledelayedexpansion 
set myfile_=C:\_D\TEST\My test file.txt 
set FirstLine= 
for /f "delims=" %%i in ('type "%myfile_%"') do (
    if not defined FirstLine set FirstLine=%%i) 
echo FirstLine=%FirstLine% 
endlocal & goto :EOF 

(Sin embargo, los llamados caracteres veneno seguirá siendo un problema.)

Más sobre el tema de conseguir una determinada línea con comandos por lotes:
  "? 23} ¿Cómo consigo el enésimo, la primera y la última línea de un archivo de texto"
  http://www.netikka.net/tsneti/info/tscmd023.htm

[Agregado 28-Ago-2012] También se puede tener

@echo off & setlocal enableextensions 
set myfile_=C:\_D\TEST\My test file.txt 
for /f "tokens=* delims=" %%a in (
    'type "%myfile_%"') do (
    set FirstLine=%%a& goto _ExitForLoop) 
:_ExitForLoop 
echo FirstLine=%FirstLine% 
endlocal & goto :EOF 

Answer 10

Prueba este

@echo off 
setlocal enableextensions enabledelayedexpansion 
set firstLine=1 
for /f "delims=" %%i in (yourfilename.txt) do (
    if !firstLine!==1 echo %%i 
    set firstLine=0 
) 
endlocal 

Answer 11

Otra forma

setlocal enabledelayedexpansion 
@echo off 
for /f "delims=" %%i in (filename.txt) do (
if 1==1 (
set first_line=%%i 
echo !first_line! 
goto :eof 
))