datos de prueba Grails unión

Question

que he escrito el siguiente controlador de Grails

class CategoryController { 

    def create = { 
     def newCategory = new CategoryCommand() 
     bindData(newCategory, params) 
     [newCategory: newCategory] 
    } 
} 

class CategoryCommand { 

    String name 
    String seoName 
} 

He escrito esta prueba de la unidad para probar el enlace de datos:

class CategoryControllerTests extends ControllerUnitTestCase { 


    void testCreate() { 

     // A new ControllerCommand should be returned if invoked with no params 
     assertNotNull controller.create() 

     // If called with params, they should be bound 
     mockParams.name = 'snooker' 
     mockParams.seoName = 'snooker-loopy' 
     def model = controller.create() 

     CategoryCommand newCategory = model.newCategory 
     assertEquals 'snooker', newCategory.name 
     assertEquals 'snooker-loopy', newCategory.seoName 

    } 
} 

pero me da esta excepción cuando es controller.create() invocado:

Ninguna firma del método: com.example.CategoryController.bindData() es aplicable para tipos de argumentos: (com.e xample.CategoryCommand, valores) org.codehaus.groovy.grails.web.taglib.GroovyPageAttributes: [com.example.CategoryCommand@7860e7d2, [:]]

Intenté funcionar esto como una prueba de integración en su lugar, pero El resultado es el mismo.

Answer 1

derecho ... me hizo un poco de excavación, y se encontró this blog page que dice (a mitad de camino hacia abajo):

---

nota: no ControllerUnitTestCase apoyo de algún método dinámico. Para instancia: bindData(). Entonces es mejor las pruebas de integración uso, o puede añadir este método para el regulador:

this.controller.metaClass.bindData = { obj, params -> 
    params.each { key, value -> 
    obj."$key" = value 
    } 
} 

---

O, que tenía un aspecto en el Grails source code, y para burlarse de él a hacer lo mismo as what Grails does, Creo que tendríamos que hacer:

import org.codehaus.groovy.grails.web.metaclass.BindDynamicMethod 

this.controller.metaClass.bindData = { obj, params -> 
    new BindDynamicMethod().invoke(delegate, BindDynamicMethod.BIND_DATA_METHOD, [ obj, params ] as Object[]) ; 
} 

(creo - No se ha probado que aunque)

Answer 2

Aquí hay dos soluciones posibles:

1. Intente ejecutarlo como una prueba de integración de nuevo. ;) Moví tu clase de prueba a la carpeta de prueba/integración y pasó por mí. También estoy ejecutando Grails 1.3.6.

2. Cambie su controlador para no utilizar bindData. Esta acción del controlador es equivalente a lo que tenemos ahora, y va a pasar su prueba de unidad:

   def create = { 
       def newCategory = new CategoryCommand(params) 
       [newCategory: newCategory] 
   } 
   

   único inconveniente es que sólo BindData puede enlazar datos de objetos asociados, si usted tiene un nombre de parámetro como "myAssociation. mi propiedad".

Answer 3

Como se mencionó anteriormente, imitando a Grails mediante el uso de BindDynamicMethod funciona. Esto funciona para mí en Grails 1.3.5:

import org.codehaus.groovy.grails.web.metaclass.BindDynamicMethod 

protected void setUp() { 
    def mc = controller.class.metaClass 
    def bind = new BindDynamicMethod() 
    mc.bindData = { Object target, Object args -> 
     bind.invoke(delegate, "bindData", [ target, args ] as Object[]) 
    } 
    mc.bindData = { Object target, Object args, List disallowed -> 
     bind.invoke(delegate, "bindData", [ target, args, [ exclude: disallowed ]] as Object[]) 
    } 
    mc.bindData = { Object target, Object args, List disallowed, String filter -> 
     bind.invoke(delegate, "bindData", [ target, args, [ exclude: disallowed ], filter ] as Object[]) 
    } 
    mc.bindData = { Object target, Object args, Map includeExclude -> 
     bind.invoke(delegate, "bindData", [ target, args, includeExclude ] as Object[]) 
    } 
    mc.bindData = { Object target, Object args, Map includeExclude, String filter -> 
     bind.invoke(delegate, "bindData", [ target, args, includeExclude, filter ] as Object[]) 
    } 
    mc.bindData = { Object target, Object args, String filter -> 
     bind.invoke(delegate, "bindData", [ target, args, filter ] as Object[]) 
    } 

} 

Esto se copia de org/codehaus/groovy/grails/plugins/web/ControllersGrailsPlugin.groovy, por lo que es compatible con todas las formas de bindData.

Esperemos que la situación mejore con los próximos Grails 1.4 y testing mixins.

Answer 4

ControllerUnitTestCase no es compatible con bindData() método.

Hay una cuestión abierta en JIRA:
Would like to see a mocked bindData() method on ControllerUnitTestCase

escribo el código mínimo para pasar la prueba de la unidad:

controller.metaClass.bindData = { obj, params -> 
    obj.properties = params 
}