¿Cuál es la mejor manera de crear un atributo de clase en Moose?

Question

Necesito un atributo de clase en Moose. Ahora estoy diciendo:

#!/usr/bin/perl 

use 5.010; 
use strict; 
use warnings; 
use MooseX::Declare; 

class User { 
    has id  => (isa => "Str", is => 'ro', builder => '_get_id'); 
    has name => (isa => "Str", is => 'ro'); 
    has balance => (isa => "Num", is => 'rw', default => 0); 

    #FIXME: this should use a database 
    method _get_id { 
     state $id = 0; #I would like this to be a class attribute 
     return $id++; 
    } 
} 

my @users; 
for my $name (qw/alice bob charlie/) { 
    push @users, User->new(name => $name); 
}; 

for my $user (@users) { 
    print $user->name, " has an id of ", $user->id, "\n"; 
} 

Answer 1

Encontré MooseX :: ClassAttribute, pero se ve feo. ¿Es esta la manera más limpia?

#!/usr/bin/perl 

use 5.010; 
use strict; 
use warnings; 
use MooseX::Declare; 

class User { 
    use MooseX::ClassAttribute; 

    class_has id_pool => (isa => "Int", is => 'rw', default => 0); 

    has id  => (isa => "Str", is => 'ro', builder => '_get_id'); 
    has name => (isa => "Str", is => 'ro'); 
    has balance => (isa => "Num", is => 'rw', default => 0); 

    #FIXME: this should use a database 
    method _get_id { 
     return __PACKAGE__->id_pool(__PACKAGE__->id_pool+1); 
    } 
} 

my @users; 
for my $name (qw/alice bob charlie/) { 
    push @users, User->new(name => $name); 
}; 

for my $user (@users) { 
    print $user->name, " has an id of ", $user->id, "\n"; 
} 

Answer 2

Honestamente, no creo que sea necesario tener todos esos problemas para los atributos de clase. Para los atributos de clase de solo lectura, solo uso un sub que devuelve una constante. Para los atributos de lectura-escritura, una variable de estado simple en el paquete por lo general hace el truco (que aún no se han topado con ningún escenario en el que necesitaba algo más complicado.)

state $count = 0; 
method _get_id { 
    return ++$count; 
} 

Un bloque privado con un léxico puede ser utilizado si necesita compatibilidad previa a 5.10.