Guardar Windows Forma Tamaño

Question

Estoy desarrollando una pieza en VB.NET. Dentro de mi formulario principal, estoy creando un nuevo formulario para usar como diálogo. Me preguntaba si había una forma de, al cerrar el nuevo diálogo, guardar su configuración de tamaño para cada usuario (probablemente en un archivo en su máquina, a través de XML o algo así)

Answer 1

puede guardarlo en el archivo de configuración y actualizarlo en el evento 'onclosing'.

para realizar una configuración vaya a Propiedades del proyecto -> configuración -> luego realice una configuración como 'tamaño de cuadro de diálogo' de tipo system.drawing.size.

luego hacer esto en su forma de diálogo:

Public Sub New() 
    InitializeComponent() 
End Sub 

Public Sub New(ByVal userSize As Size) 
    InitializeComponent() 
    Me.Size = userSize 
End Sub 

Protected Overrides Sub OnClosing(ByVal e As System.ComponentModel.CancelEventArgs) 
    MyBase.OnClosing(e) 
    My.Settings.DialogSize = Me.Size 
    My.Settings.Save() 
End Sub 

hacer algo como esto para comprobar y utilizar la configuración:

Dim dlg As MyDialogWindow 
    If My.Settings.DialogSize.IsEmpty Then 
     dlg = New MyDialogWindow() 
    Else 
     dlg = New MyDialogWindow(My.Settings.DialogSize) 
    End If 
    dlg.ShowDialog() 

Answer 2

Aunque this is for C#, ayudará con VB.Net también.

Answer 3

También puede hacerlo utilizando la interfaz de usuario proporcionada por el propio IDE de VB.NET. En el panel de propiedades de un formulario, busque en el elemento denominado "(Configuración de la aplicación)" y luego en "Enlace de propiedad". Puede vincular casi todas las propiedades del formulario (incluido el tamaño y la ubicación) a un valor de configuración para esa aplicación.

Answer 4

Como resultado, he encontrado una manera de hacer esto utilizando la System.IO.IsolatedStorage

Answer 5

Usted puede también añadir un nuevo ajuste a su aplicación (tamaño) y configurarlo para que system.drawing.size

Luego, asegúrese de guardar el tamaño actual en la configuración al cerrar.

Private Sub myForm_FormClosing(ByVal sender As System.Object, 
          ByVal e As System.Windows.Forms.FormClosingEventArgs) _ 
          Handles MyBase.FormClosing 

    My.Settings.size = Me.Size 
    My.Settings.Save() 

End Sub 

y de la carga de aplicar el tamaño que haya guardado en la configuración

Private Sub myForm_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) _ 
    Handles MyBase.Load 
    ' if this is the first time to load the form 
    ' dont set the size (the form will load with the size in the designe) 
    If Not My.Settings.size.IsEmpty Then 
     Me.Size = My.Settings.size 
    End If 
End Sub