Inno Setup - Desinstalar la opción de eliminación del registro

Question

El programa que estoy construyendo un instalador usa las entradas de registro para almacenar la configuración del usuario. En este momento lo tengo configurado para eliminar dichos archivos de registro cuando se desinstala el programa, pero me gustaría la posibilidad de dar a los usuarios la opción de conservar o eliminar los archivos de registro después de la desinstalación.

No soy el mejor programador/programador, por lo que cuanto más simple sea la respuesta, mejor.

Mi registro/desinstalación se ve así actualmente.

[Registry] 
    Root: HKCU; Subkey: "Software\FFSPLIT Overlay Filter"; Flags: uninsdeletekey 


    [UninstallDelete] 
    Type: filesandordirs; Name: "{app}\ffmpeg" 
    Type: filesandordirs; Name: "{app}\OverlayData" 
    Type: files; Name: "{app}\AForge.Controls.dll" 
    Type: files; Name: "{app}\AForge.Imaging.dll" 
    Type: files; Name: "{app}\AForge.Video.DirectShow.dll" 
    Type: files; Name: "{app}\AForge.Video.dll" 
    Type: files; Name: "{app}\AudioFilter.ax" 
    Type: files; Name: "{app}\default.cfg" 
    Type: files; Name: "{app}\DirectShowLib-2005.dll" 
    Type: files; Name: "{app}\ffmpeg.exe" 
    Type: files; Name: "{app}\FFSplit Overlay Filter.ax" 
    Type: files; Name: "{app}\FFsplit.exe" 
    Type: files; Name: "{app}\FFSplitOverlayManager.exe" 
    Type: files; Name: "{app}\librtmp.dll" 
    Type: files; Name: "{app}\msvcp100d.dll" 
    Type: files; Name: "{app}\msvcr100d.dll" 
    Type: files; Name: "{app}\NAudio.dll" 
    Type: files; Name: "{app}\RegisterFilter.bat" 
    Type: files; Name: "{app}\setting.cfg" 
    Type: files; Name: "{app}\UNRegisterFilter.bat" 
    Type: files; Name: "{app}\wavbuffer" 
    Type: files; Name: "{app}\Micfilter.ax" 

Answer 1

InnoSetup no tiene ningún parámetro de comprobación de desinstalación condicional, por lo que debe hacerlo usted mismo. Por lo tanto, debe eliminar el indicador uninsdeletekey que eliminaría automáticamente la clave de registro y, al final del proceso de desinstalación, puede preguntar al usuario si desea eliminar esa clave (de alguna manera significativa) y eliminarla manualmente. El siguiente script hace esto en el paso posterior a la desinstalación, ¿cuál es el momento en que la aplicación se desinstaló correctamente? Puede seguir el commented version:

[Setup] 
AppName=My Program 
AppVersion=1.5 
DefaultDirName={pf}\My Program 

#define FilterRegKey "Software\FFSPLIT Overlay Filter" 

[Registry] 
Root: HKCU; Subkey: "{#FilterRegKey}" 

[Code] 
procedure CurUninstallStepChanged(CurUninstallStep: TUninstallStep); 
begin 
    if CurUninstallStep = usPostUninstall then 
    begin 
    if RegKeyExists(HKEY_CURRENT_USER, '{#FilterRegKey}') then 
     if MsgBox('Do you want to delete the overlay filter registry key ?', 
     mbConfirmation, MB_YESNO) = IDYES 
     then 
     RegDeleteKeyIncludingSubkeys(HKEY_CURRENT_USER, '{#FilterRegKey}'); 
    end; 
end;