cómo volver a lanzar la misma excepción en el servidor sql

Question

Quiero volver a lanzar la misma excepción en el servidor sql que se ha producido en mi bloque try. Puedo lanzar el mismo mensaje pero quiero lanzar el mismo error.

BEGIN TRANSACTION 
    BEGIN TRY 
      INSERT INTO Tags.tblDomain 
      (DomainName, SubDomainId, DomainCode, Description) 
      VALUES(@DomainName, @SubDomainId, @DomainCode, @Description) 
      COMMIT TRANSACTION 
    END TRY 

    BEGIN CATCH 
      declare @severity int; 
      declare @state int; 

      select @severity=error_severity(), @state=error_state(); 

      RAISERROR(@@Error,@ErrorSeverity,@state); 
      ROLLBACK TRANSACTION 
    END CATCH 

RAISERROR(@@Error, @ErrorSeverity, @state);

Esta línea mostrará el error, pero quiero funcionalidad algo por el estilo. Esto genera error con número de error 50000, pero quiero número Erron a ser arrojado que estoy pasando @@error,

Quiero capturar este error hay en el frontend

es decir

catch (SqlException ex) 
{ 
if ex.number==2627 
MessageBox.show("Duplicate value cannot be inserted"); 
} 

quiero esta funcionalidad que no se puede lograr usando raiseerror. No quiero dar un mensaje de error personalizado al final.

RAISEERROR debe devolver error mencionado más adelante cuando paso ErrorNo a ser lanzado en la captura

Msg 2627, Level 14, State 1, Procedure spOTest_DomainInsert, 

Línea 14 Violación de Unique 'UK_DomainCode' CLAVE restricción. No se puede insertar la clave duplicada en el objeto 'Tags.tblDomain'. La declaración ha finalizado.

EDIT:

Cuál puede ser el inconveniente de no usar bloqueador intento de captura si quiero excepción que se maneja en frontend considerando procedimiento almacenado contiene varias consultas que necesitan ser ejecutados

Answer 1

Aquí hay una muestra de código de limpieza completamente funcional para revertir una serie de declaraciones si se produce un error e informar el mensaje de error.

begin try 
    begin transaction; 

    ... 

    commit transaction; 
end try 
begin catch 
    declare @ErrorMessage nvarchar(max), @ErrorSeverity int, @ErrorState int; 
    select @ErrorMessage = ERROR_MESSAGE() + ' Line ' + cast(ERROR_LINE() as nvarchar(5)), @ErrorSeverity = ERROR_SEVERITY(), @ErrorState = ERROR_STATE(); 
    rollback transaction; 
    raiserror (@ErrorMessage, @ErrorSeverity, @ErrorState); 
end catch 

Answer 2

I piensa que sus opciones son:

• Dont detectar el error (dejar que la burbuja hacia arriba)
• Eleve uno personalizado

En algún momento, SQL probablemente presentará un comando de re-publicación o la capacidad de atrapar solo ciertos errores. Pero por ahora, use una solución alternativa. Lo siento.

Answer 3

Ok, esto es una solución ... :-)

DECLARE @Error_Number INT 
BEGIN TRANSACTION 
    BEGIN TRY 
    INSERT INTO Test(Id, Name) VALUES (newID(),'Ashish') 
    /* Column 'Name' has unique constraint on it*/ 
    END TRY 
    BEGIN CATCH 

      SELECT ERROR_NUMBER() 
      --RAISERROR (@ErrorMessage,@Severity,@State) 
      ROLLBACK TRAN 
    END CATCH 

Si se observa el bloque catch, No es elevar el error pero volviendo el número de error real (y también podría deshacer la transacción) . Ahora, en su código .NET, en lugar de detectar la excepción , si usa ExecuteScalar(), obtendrá el número de error real que desea y mostrará el número apropiado.

int errorNumber=(int)command.ExecuteScalar(); 
if(errorNumber=<SomeNumber>) 
{ 
    MessageBox.Show("Some message"); 
} 

Espero que esto ayude,

EDIT: - Sólo una nota, si desea obtener el número de registros afectados y tratando de utilizar ExecuteNonQuery, la solución anterior puede no funcionar para usted.De lo contrario, creo que se adaptaría a lo que necesita. Házmelo saber.

Answer 4

Usted no puede: sólo el motor puede arrojar errores menores al 50000. Todo lo que se puede hacer es lanzar una excepción que se ve igual ...

See my answer here please

La pregunta aquí utilizado transacciones del lado del cliente para hacer lo que quería que creo que es un poco tonto ...

Answer 5

Desde el punto de vista del diseño, ¿qué sentido tiene arrojar excepciones con números de error originales y mensajes personalizados? Hasta cierto punto, rompe el contrato de interfaz entre las aplicaciones y la base de datos. Si desea detectar errores originales y manejarlos en un código más alto, no los maneje en la base de datos. Luego, cuando atrape una excepción, puede cambiar el mensaje presentado al usuario a cualquier cosa que desee. Sin embargo, no lo haría, porque hace que el código de su base de datos hmm 'no sea correcto'. Como otros dijeron, debes definir un conjunto de tus propios códigos de error (por encima de 50000) y lanzarlos en su lugar. A continuación, puede solucionar los problemas de integridad ('Duplicar valores no están permitidos') por separado de posibles problemas comerciales: 'Código postal no es válido', 'No se encontraron filas que coincidan con los criterios', etc.

Answer 6

SQL 2012 introduce la instrucción throw:

http://msdn.microsoft.com/en-us/library/ee677615.aspx

Si no se especifica la sentencia throw sin parámetros, debe aparecer dentro de un bloque CATCH. Esto provoca que la excepción atrapada se eleve.

BEGIN TRY 
    BEGIN TRANSACTION 
    ... 
    COMMIT TRANSACTION 
END TRY 
BEGIN CATCH 
    ROLLBACK TRANSACTION; 
    THROW 
END CATCH 

Answer 7

La manera de detener la ejecución en un procedimiento almacenado después de que ha ocurrido un error y la burbuja el error de nuevo al programa de llamada es seguir cada declaración que podría producir un error con este código:

If @@ERROR > 0 
Return 

Me sorprendí a mí mismo al descubrir que la ejecución en un procedimiento almacenado puede continuar después de un error, sin darse cuenta de esto puede dar lugar a algunos errores difíciles de rastrear.

Este tipo de paralelos de tratamiento de errores (pre) .Net Visual Basic 6. Mirando hacia adelante a la orden del tiro en SQL Server 2012.

Answer 8

Teniendo en cuenta que no se ha mudado a 2012, sin embargo, una manera de poner en práctica el El borboteo del código de error original es usar la parte del mensaje de texto de la excepción que está (re) lanzando desde el bloque catch. Recuerde que puede contener alguna estructura, por ejemplo, texto XML para que su código de llamada pueda analizarse en su bloque catch.

Answer 9

Regeneración de dentro del bloque CATCH (código de pre-SQL2012, sentencia use lanzar para SQL2012 y posteriores):

DECLARE 
    @ErrorMessage nvarchar(4000) = ERROR_MESSAGE(), 
    @ErrorNumber int = ERROR_NUMBER(), 
    @ErrorSeverity int = ERROR_SEVERITY(), 
    @ErrorState int = ERROR_STATE(), 
    @ErrorLine int = ERROR_LINE(), 
    @ErrorProcedure nvarchar(200) = ISNULL(ERROR_PROCEDURE(), '-'); 
SELECT @ErrorMessage = N'Error %d, Level %d, State %d, Procedure %s, Line %d, ' + 'Message: ' + @ErrorMessage; 
RAISERROR (@ErrorMessage, @ErrorSeverity, 1, @ErrorNumber, @ErrorSeverity, @ErrorState, @ErrorProcedure, @ErrorLine) 

Answer 10

También puede crear un contenedor procedimiento almacenado para los esos escenarios cuando desee que la instrucción SQL para ser ejecutado dentro de la transacción y alimentar el error hasta su código.

CREATE PROCEDURE usp_Execute_SQL_Within_Transaction 
(
    @SQL nvarchar(max) 
) 
AS 

SET NOCOUNT ON 

BEGIN TRY 
    BEGIN TRANSACTION 
     EXEC(@SQL) 
    COMMIT TRANSACTION 
END TRY 

BEGIN CATCH 
    DECLARE @ErrorMessage nvarchar(max), @ErrorSeverity int, @ErrorState int 
    SELECT @ErrorMessage = N'Error Number: ' + CONVERT(nvarchar(5), ERROR_NUMBER()) + N'. ' + ERROR_MESSAGE() + ' Line ' + CONVERT(nvarchar(5), ERROR_LINE()), @ErrorSeverity = ERROR_SEVERITY(), @ErrorState = ERROR_STATE() 
    ROLLBACK TRANSACTION 
    RAISERROR (@ErrorMessage, @ErrorSeverity, @ErrorState) 
END CATCH 

GO 

-- Test it 
EXEC usp_Execute_SQL_Within_Transaction @SQL = 'SELECT 1; SELECT 2' 
EXEC usp_Execute_SQL_Within_Transaction @SQL = 'SELECT 1/0; SELECT 2' 
EXEC usp_Execute_SQL_Within_Transaction @SQL = 'EXEC usp_Another_SP'