¿Cómo puedo abrir y guardar programáticamente una presentación de PowerPoint como HTML/JPEG en C# o Perl?

Question

Estoy buscando un fragmento de código que haga esto, preferiblemente en C# o incluso en Perl.

espero que esto no es una gran tarea;)

Answer 1

Como Kev puntos fuera, no utilice esta en un servidor web. Sin embargo, el siguiente script Perl es perfectamente bien para la conversión de archivos sin conexión, etc:

#!/usr/bin/perl 

use strict; 
use warnings; 

use Win32::OLE; 
use Win32::OLE::Const 'Microsoft PowerPoint'; 
$Win32::OLE::Warn = 3; 

use File::Basename; 
use File::Spec::Functions qw(catfile); 

my $EXPORT_DIR = catfile $ENV{TEMP}, 'ppt'; 

my ($ppt) = @ARGV; 
defined $ppt or do { 
    my $progname = fileparse $0; 
    warn "Usage: $progname output_filename\n"; 
    exit 1; 
}; 

my $app = get_powerpoint(); 
$app->{Visible} = 1; 

my $presentation = $app->Presentations->Open($ppt); 
die "Could not open '$ppt'\n" unless $presentation; 

$presentation->Export(
    catfile($EXPORT_DIR, basename $ppt), 
    'JPG', 
    1024, 
    768, 
); 

sub get_powerpoint { 
    my $app; 
    eval { $app = Win32::OLE->GetActiveObject('PowerPoint.Application') }; 
    die "$@\n" if $@; 

    unless(defined $app) { 
     $app = Win32::OLE->new('PowerPoint.Application', 
      sub { $_[0]->Quit } 
     ) or die sprintf(
      "Cannot start PowerPoint: '%s'\n", Win32::OLE->LastError 
     ); 
    } 
    return $app; 
} 

Answer 2

A continuación se abrirá C:\presentation1.ppt y guardar las diapositivas como C:\Presentation1\slide1.jpg etc.

Si usted necesita para obtener el ensamblado de interoperabilidad, es disponible en 'Herramientas' en el programa de instalación de Office, o puede descargarlo desde here (office 2003). Debería poder encontrar los enlaces para otras versiones desde allí si tiene una versión más nueva de la oficina.

using Microsoft.Office.Core; 
using PowerPoint = Microsoft.Office.Interop.PowerPoint; 

namespace PPInterop 
{ 
    class Program 
    { 
    static void Main(string[] args) 
    { 
     var app = new PowerPoint.Application(); 

     var pres = app.Presentations; 

     var file = pres.Open(@"C:\Presentation1.ppt", MsoTriState.msoTrue, MsoTriState.msoTrue, MsoTriState.msoFalse); 

     file.SaveCopyAs(@"C:\presentation1.jpg", Microsoft.Office.Interop.PowerPoint.PpSaveAsFileType.ppSaveAsJPG, MsoTriState.msoTrue); 
    } 
    } 
} 

Editar: Sinan's version usando la exportación parece ser un poco mejor opción ya que se puede especificar una resolución de salida. Para C#, cambiar la última línea anterior a:

file.Export(@"C:\presentation1.jpg", "JPG", 1024, 768);