punto individual colorante en ListPlot, ErrorListPlot en Mathematica

Question

puedo conseguir un color ListLinePlot haciendo algo como

ListLinePlot[Range[420, 680, 20], ColorFunction -> "VisibleSpectrum", ColorFunctionScaling -> False] 

Sin embargo, como se indica en el archivo de ayuda (" ColorFunction requiere al menos un conjunto de datos ser Joined "), si hago el equivalente

ListPlot[Range[420, 680, 20], ColorFunction -> "VisibleSpectrum", ColorFunctionScaling -> False] 

todos mis puntos son azules. ¿Hay alguna manera de hacer que ColorFunction funcione en ListPlot con Joined -> False?

Es decir, hay una manera más agradable para conseguir algo como

ListPlot[ 
List /@ Transpose[{Range[(680 - 420)/20 + 1], Range[420, 680, 20]}], 
PlotMarkers -> ({Graphics[{#, Disk[]}], 0.05} & /@ ColorData["VisibleSpectrum"] /@ Range[420, 680, 20]) 
] 

?

(Además, ¿alguien tiene una explicación de por qué Mathematica requiere Joined -> True con el fin de hacer uso de ColorFunction?)

Editar: Yo también estoy buscando una manera de hacer una coloración similar con ErrorListPlot en el paquete ErrorBarPlots.

Answer 1

El problema es que Join-> True dibuja una línea [] a la que se le puede dar VertexColors por cada punto que lo contenga. Supongo que hacer lo mismo con los puntos cuando configurar Unidos> False conduce a situaciones en las que no funciona. Sin embargo, Line [] y Point [] funcionan más o menos igual en su caso.Entonces, ¿se trata de

ListLinePlot[Range[420, 680, 20], ColorFunction -> "VisibleSpectrum", 
    ColorFunctionScaling -> False] /. Line[arg___] :> Point[arg] 

Y, por cierto, si el uso de solamente un ListLinePlot, donde las únicas directivas de línea [] que surgen son el de sus datos, esto debería funcionar incluso si tener más conjuntos de datos y {x, y} coordina

data = Transpose[Table[{{x, Sin[x]}, {x, Cos[x]}}, {x, 0, 2 Pi, 0.2}]]; 
ListLinePlot[data, ColorFunction -> Hue] /. Line[arg___] :> Point[arg] 

Answer 2

Puede utilizar DiscretePlot:

data = Range[420, 680, 20]; 
DiscretePlot[data[[i]], {i, Length[data]}, 
    ColorFunction -> "VisibleSpectrum", ColorFunctionScaling -> False, 
    Filling -> None] 

Si está trazando una lista de puntos xey, se pone un poco más complicado:

data = Transpose[{Range[420, 680, 20], Range[400, 530, 10]}]; 
mapping = Apply[Rule, data, 2]; 
DiscretePlot[i/.mapping, {i, data[[;;,1]]}, 
    ColorFunction -> "VisibleSpectrum", ColorFunctionScaling -> False, 
    Filling -> None] 

Parece bastante extraño que DiscretePlot le permitirá colorear los puntos de manera diferente, mientras que ListPlot no lo hará. Estoy seguro de que debe tener algo que ver con los detalles de la implementación, pero no puedo pensar en una razón por la cual ese sería el caso.

Answer 3

me encontré con este problema en mi trabajo también. I asignar un color a cada punto de la siguiente manera:

data = ... 
ListPlot[data] /. Point[args___] :> Point[args, VertexColors -> {c1, c2, ...}] 

donde c1 es el color para el primer punto de datos, y así sucesivamente. La lista de color puede ser mediante programación genera, por ejemplo

ColorData["Rainbow"] /@ (Range@Length@data/Length@data) 

Here is the result.

Los puntos positivos de este método son como sigue.

• Es sencillo: tenemos una lista de pares, luego creamos una lista de colores correspondiente.
• Nuestro código original ListPlot no necesita ser modificado (por ejemplo, cambiado a ListLinePlot).