XSLT valor de variable predeterminado si el valor no está presente

Question

Estoy tratando de declarar una variable que tiene un valor predeterminado o si un valor está presente en un conjunto repetitivo para usar un nuevo valor diferente.

Esto es lo que tengo hasta ahora.

 <xsl:variable name="lsind"> 
     <xsl:value-of select="'N'"/> 

     <xsl:for-each select='./Plan/InvestmentStrategy/FundSplit'> 
      <xsl:choose> 
      <xsl:when test="contains(./@FundName, 'Lifestyle')"> 
       <xsl:value-of select="'Y'"/> 
      </xsl:when> 
      </xsl:choose> 
     </xsl:for-each> 
     </xsl:variable> 

Lo que quiero decir, si todas las instancias de ./Plan/InvestmentStrategy/FundSplit/@FundName 'contiene' estilo de vida entonces lsind 'Y' de lo contrario se cae de nuevo al valor por defecto de 'N'.

Lo estoy haciendo de esta manera como si utilizo 'de lo contrario, la última ocurrencia podría volver a poner lsind en N?

¿Alguna sugerencia?

Answer 1

<xsl:variable name="lsind"> 
    <xsl:choose> 
    <xsl:when test="Plan/InvestmentStrategy/FundSplit[contains(@FundName, 'Lifestyle')]"> 
     <xsl:text>Y</xsl:text> 
    </xsl:when> 
    <xsl:otherwise> 
     <xsl:text>N</xsl:text> 
    </xsl:otherwise> 
    </xsl:choose> 
</xsl:variable> 

debería ser suficiente

Answer 2

Esto puede especificarse en una sola expresión XPath (incluso en XPath 1.0):

<xsl:variable name="vLsind" select= 
"substring('YN', 
      2 - boolean(plan/InvestmentStrategy/FundSplit[@FundName='Lifestyle']), 
      1)"/> 

Ejemplo 1:

<plan> 
<InvestmentStrategy> 
    <FundSplit FundName="Lifestyle"/> 
</InvestmentStrategy> 
</plan> 

Transformación:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:variable name="vLsind" select= 
"substring('YN', 
      2 - boolean(plan/InvestmentStrategy/FundSplit[@FundName='Lifestyle']), 
      1)"/> 

<xsl:template match="/"> 
    <xsl:value-of select="$vLsind"/> 
</xsl:template> 
</xsl:stylesheet> 

Resultado:

Y 

Ejemplo 2:

<plan> 
<InvestmentStrategy> 
    <FundSplit FundName="No Lifestyle"/> 
</InvestmentStrategy> 
</plan> 

Resultado:

N 

Explicación:

1. Por definición boolean(some-node-set) es true() exactamente cuando some-node-set es no vacío.

2. Por definición number(true()) es 1 y number(false()) es 0

3. 1 y 2 cobined nos da: number(boolean(some-node-set)) es 1 exactamente cuando some-node-set es no vacío, de lo contrario es 0.

Otras soluciones de una sola expresión:

XPath 1.0:

translate(number(boolean(YourXPathExpression)), '10', 'YN') 

XPath 2.0:

if(YourXPathExpression) 
then 'Y' 
else 'N' 

O incluso:

('N', 'Y')[number(boolean(YourXPathExpression)) +1]