Cómo llamar a una función/procedimiento de forma asíncrona en Delphi (Sin componentes)

Question

Estoy intentando ejecutar una función o procedimiento en Delphi de forma asíncrona, pero sin utilizar un componente, ¿hay alguna manera de hacerlo con las funciones delphi core?

Answer 1

Es posible que también desee ejecutar su procedimiento en un hilo. Use luego el evento OnTerminate para obtener el resultado. Sí, en estos días de .NET y C# estamos algo mimados con la forma fácil y conveniente de ejecutar métodos asincrónicamente, pero así es como funciona en Delphi.

Answer 2

Si está preguntando si el VCL tiene algo like BeginInvoke in .NET listo para usar, entonces la respuesta es no. Sin embargo, puede obtener algo muy similar en la forma de una pequeña unidad que vincula a su programa, la biblioteca AsyncCalls de Andreas Hausladen. No es un componente, así que supongo que califica. También es compatible con Delphi desde la versión 5 en adelante. Muy recomendado

Editar:

Voy a añadir un ejemplo ya que usted no ponerlo en marcha. Si obtiene un bloqueo en su código de llamada, entonces su problema es que no se mantiene ninguna referencia al puntero de interfaz IAsyncCall que devolvió la función. El objeto que implementa la interfaz se destruirá inmediatamente cuando la referencia temporal salga del alcance. Se llamará al destructor en el contexto del hilo VCL, y llamará al WaitForSingleObject() o una función similar para esperar a que termine el hilo del trabajador. El resultado de eso es que su hilo VCL bloquea.

obtendrá el comportamiento correcto si se mantiene una referencia al puntero de interfaz:

type 
    TForm1 = class(TForm) 
    Button1: TButton; 
    Timer1: TTimer; 
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean); 
    procedure Button1Click(Sender: TObject); 
    procedure Timer1Timer(Sender: TObject); 
    private 
    fAsyncCall: IAsyncCall; 
    procedure WaitForIt(ADelay: integer); 
    end; 

Ajuste el temporizador debe ser inhabilitado y hacer que tenga un tiempo muy corto Interval, dicen que 50 ms. El clic de botón inicia la operación asíncrona:

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    Button1.Enabled := FALSE; 
    fAsyncCall := AsyncCall(WaitForIt, 1000); 
end; 

procedure TForm1.WaitForIt(ADelay: integer); 
begin 
    Sleep(ADelay); 

    EnterMainThread; 
    try 
    Randomize; 
    Color := RGB(Random(256), Random(256), Random(256)); 
    Timer1.Enabled := TRUE; 
    finally 
    LeaveMainThread; 
    end; 
end; 

Mientras la operación está activa no se puede iniciar ninguna otra. Al finalizar el temporizador que permite notificar a la forma y restablecer la referencia de interfaz:

procedure TForm1.Timer1Timer(Sender: TObject); 
begin 
    Timer1.Enabled := FALSE; 
    Assert((fAsyncCall <> nil) and fAsyncCall.Finished); 
    fAsyncCall := nil; 
    Button1.Enabled := TRUE; 
end; 

procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean); 
begin 
    CanClose := (fAsyncCall = nil) or fAsyncCall.Finished; 
end; 

Nota cómo es posible incluso para acceder al formulario directamente desde el método llamado, mediante el uso de EnterMainThread() y LeaveMainThread().

El código anterior no es el mínimo absoluto, solo pretende demostrar algunas ideas.